git.maemo.org Git - pkg-perl/blob - deb-src/libsub-uplevel-perl/libsub-uplevel-perl-0.1901/inc/Module/Build/WikiDoc.pm

   1 package Module::Build::WikiDoc;
   2 use strict;
   3 use base qw/Module::Build/;
   4 use File::Spec;
   5
   6 sub ACTION_wikidoc {
   7     my $self = shift;
   8     eval "use Pod::WikiDoc";
   9     if ( $@ eq '' ) {
  10         my $parser = Pod::WikiDoc->new({
  11             comment_blocks => 1,
  12             keywords => { VERSION => $self->dist_version },
  13         });
  14         for my $src ( keys %{ $self->find_pm_files() } ) {
  15             (my $tgt = $src) =~ s{\.pm$}{.pod};
  16             $parser->filter( {
  17                 input   => $src,
  18                 output  => $tgt,
  19             });
  20             print "Creating $tgt\n";
  21             $tgt =~ s{\\}{/}g;
  22             $self->_add_to_manifest( 'MANIFEST', $tgt );
  23         }
  24     }
  25     else {
  26         warn "Pod::WikiDoc not available. Skipping wikidoc.\n";
  27     }
  28 }
  29
  30 sub ACTION_test {
  31     my $self = shift;
  32     my $missing_pod;
  33     for my $src ( keys %{ $self->find_pm_files() } ) {
  34         (my $tgt = $src) =~ s{\.pm$}{.pod};
  35         $missing_pod = 1 if ! -e $tgt;
  36     }
  37     if ( $missing_pod ) {
  38         $self->depends_on('wikidoc');
  39         $self->depends_on('build');
  40     }
  41     $self->SUPER::ACTION_test;
  42 }
  43
  44 sub ACTION_testpod {
  45     my $self = shift;
  46     $self->depends_on('wikidoc');
  47     $self->SUPER::ACTION_testpod;
  48 }
  49
  50 sub ACTION_distmeta {
  51     my $self = shift;
  52     $self->depends_on('wikidoc');
  53     $self->SUPER::ACTION_distmeta;
  54 }
  55
  56 1;