git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 VERSION = 0.5.1
   8 USE_RESOURCES = 0
   9
  10 QT += webkit network
  11 CONFIG += qt webkit mobility
  12 MOBILITY = location
  13
  14 contains(MEEGO_EDITION,harmattan) {
  15     CONFIG += harmattan
  16 }
  17
  18 sailfish {
  19     QT += qml quick concurrent webkitwidgets
  20     PLATFORM = sailfish
  21     DEFINES += TARGET_PLATFORM_SAILFISH
  22     # enable booster
  23     CONFIG += qdeclarative-boostable
  24     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden -Wno-psabi
  25     QMAKE_LFLAGS += -pie -rdynamic
  26     PLATFORM_SOURCES = view.cpp
  27     PLATFORM_HEADERS = view.h
  28 }
  29 harmattan {
  30     QT += declarative
  31     PLATFORM = harmattan
  32     DEFINES += TARGET_PLATFORM_HARMATTAN
  33     # enable booster
  34     CONFIG += qdeclarative-boostable
  35     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden -Wno-psabi
  36     QMAKE_LFLAGS += -pie -rdynamic
  37     PLATFORM_SOURCES = view.cpp
  38     PLATFORM_HEADERS = view.h
  39 }
  40 maemo5 {
  41     QT += maemo5
  42     PLATFORM = fremantle
  43     DEFINES += TARGET_PLATFORM_FREMANTLE
  44     PLATFORM_SOURCES = \
  45         app.cpp \
  46         stationlistview.cpp \
  47         stationview.cpp \
  48         settingsdialog.cpp \
  49         keypressforwarder.cpp
  50     PLATFORM_HEADERS= \
  51         app.h \
  52         stationlistview.h \
  53         keypressforwarder.h \
  54         settingsdialog.h \
  55         stationview.h
  56 }
  57 symbian {
  58     QT += declarative
  59     DEFINES += TARGET_PLATFORM_SYMBIAN
  60     PLATFORM = symbian
  61     PLATFORM_SOURCES = view.cpp
  62     PLATFORM_HEADERS = view.h
  63 }
  64 !sailfishos:!harmattan:!maemo5:!symbian {
  65     PLATFORM = desktop
  66     DEFINES += TARGET_PLATFORM_DESKTOP
  67     PLATFORM_SOURCES = view.cpp
  68 }
  69
  70 message(Compiling For:    $$PLATFORM)
  71 message(Platform Sources: $$PLATFORM_SOURCES)
  72 message(Qt Modules Used:  $$QT)
  73 message(Building version: $$VERSION)
  74
  75 TARGET = quandoparte
  76 TEMPLATE = app
  77 VERSION_STRING = '\\"$${VERSION}\\"'
  78 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  79
  80 contains(USE_RESOURCES,1) {
  81     DEFINES += USE_RESOURCES=1
  82 }
  83
  84 !debug {
  85     DEFINES += QT_NO_DEBUG_OUTPUT
  86 }
  87
  88 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  89
  90 SOURCES += \
  91     $$PLATFORM_SOURCES \
  92     main.cpp \
  93     stationlistmodel.cpp \
  94     stationlistproxymodel.cpp \
  95     settings.cpp \
  96     dataprovider.cpp \
  97     stationschedulemodel.cpp \
  98     stationscheduleitem.cpp
  99
 100 HEADERS += \
 101     $$PLATFORM_HEADERS \
 102     stationlistmodel.h \
 103     stationlistproxymodel.h \
 104     settings.h \
 105     dataprovider.h \
 106     stationschedulemodel.h \
 107     stationscheduleitem.h
 108
 109 FORMS += \
 110     settingsdialog.ui \
 111     stationlistview.ui
 112
 113 symbian {
 114     TARGET.UID3 = 0xe30fb688
 115     # TARGET.CAPABILITY +=
 116     TARGET.EPOCSTACKSIZE = 0x14000
 117     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
 118 }
 119
 120 QMLSOURCES = \
 121     resources/harmattan/qml/main.qml \
 122     resources/harmattan/qml/StationListPage.qml \
 123     resources/harmattan/qml/StationPage.qml \
 124     resources/harmattan/qml/SearchBar.qml \
 125     resources/harmattan/qml/PageHeader.qml \
 126     resources/harmattan/qml/PageHeader.js \
 127     resources/harmattan/qml/uiconstants.js \
 128     resources/harmattan/qml/StationListPage.js \
 129     resources/harmattan/qml/AboutPage.qml \
 130     resources/harmattan/qml/InfoBar.qml \
 131     resources/harmattan/qml/DroppedShadow.qml \
 132     resources/harmattan/qml/DelayIndicator.qml \
 133     resources/harmattan/qml/StationScheduleDelegate.qml
 134
 135 OTHER_FILES += \
 136     resources/harmattan/applications/quandoparte.desktop \
 137     resources/fremantle/applications/quandoparte.desktop \
 138     icons/48x48/quandoparte.png \
 139     icons/64x64/quandoparte.png \
 140     icons/80x80/quandoparte.png \
 141     icons/scalable/quandoparte.svg \
 142     icons/quandoparte.png \
 143     resources/quandoparte.css \
 144     resources/arrivals.css \
 145     resources/departures.css \
 146     $$replace(TRANSLATIONS, .ts, .qm) \
 147     resources/stations/stations.qpl \
 148     resources/stations/generatelist.xq \
 149     resources/stations/generateunclassifiedlist.xq \
 150     $$QMLSOURCES
 151
 152 unix {
 153     isEmpty(PREFIX) {
 154         maemo5 {
 155             PREFIX=/opt/usr
 156         }
 157         harmattan {
 158             PREFIX=/opt/$${TARGET}
 159         }
 160         sailfish:desktop {
 161             PREFIX=/usr/local
 162         }
 163     }
 164     maemo5 {
 165         DESKTOPDIR=/usr/share/applications/hildon
 166     }
 167     sailfish:harmattan {
 168         DESKTOPDIR=/usr/share/applications
 169     }
 170     desktop {
 171         DESKTOPDIR=$$PREFIX/share/applications
 172     }
 173
 174     BINDIR=$$PREFIX/bin
 175     contains(USE_RESOURCES,1) {
 176         DATADIR=":"
 177     } else {
 178         DATADIR=$$PREFIX/share/apps/$${TARGET}
 179     }
 180     DEFINES += DATADIR=\\\"$${DATADIR}\\\" PKGDATADIR=\\\"$${PKGDATADIR}\\\"
 181 }
 182
 183 message(Installing to prefix $$PREFIX)
 184
 185 unix:!symbian {
 186     target.path = $$BINDIR
 187     INSTALLS += target
 188 }
 189
 190 unix:!symbian {
 191     desktopfile.files = resources/$$PLATFORM/applications/$${TARGET}.desktop
 192     desktopfile.path = $$DESKTOPDIR
 193     INSTALLS += desktopfile
 194 }
 195
 196 unix:!symbian {
 197     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 198     stations.files = resources/stations/stations.qpl
 199
 200     i18n.path = $$DATADIR/i18n
 201     stations.path = $$DATADIR/stations
 202
 203     icon48.files = icons/48x48/$${TARGET}.png
 204     icon64.files = icons/64x64/$${TARGET}.png
 205     iconscalable.files = icons/scalable/$${TARGET}.svg
 206
 207     icon48.path = /usr/share/icons/hicolor/48x48/apps
 208     icon64.path = /usr/share/icons/hicolor/64x64/apps
 209     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 210
 211     INSTALLS += icon48
 212     INSTALLS += iconscalable
 213     !contains(USE_RESOURCES,1) {
 214         INSTALLS += i18n
 215         INSTALLS += stations
 216     }
 217 }
 218
 219 maemo5 {
 220     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 221     css.path = $$DATADIR/css
 222     !contains(USE_RESOURCES,1) {
 223         INSTALLS += css
 224     }
 225 }
 226
 227 sailfish {
 228     icon90.files = icons/90x90/$${TARGET}.png
 229     icon90.path = /usr/share/icons/hicolor/meegotouch/apps
 230     INSTALLS += icon90
 231 }
 232 harmattan {
 233     icon80.files = icons/80x80/$${TARGET}.png
 234     icon80.path = /usr/share/icons/hicolor/meegotouch/apps
 235     INSTALLS += icon80
 236 }
 237
 238 !contains(USE_RESOURCES,1) {
 239     harmattan {
 240         qml.files = resources/harmattan/qml/*.qml resources/harmattan/qml/*.js
 241         qml.path = $$DATADIR/qml
 242         INSTALLS += qml
 243     }
 244 }
 245
 246 contains(USE_RESOURCES,1) {
 247     RESOURCES += \
 248         quandoparte.qrc
 249 }
 250
 251 hack_to_fix_translations {
 252     SOURCES += $$QMLSOURCES
 253 }