QT += core gui maemo5 declarative

TARGET = quick-widgets
TEMPLATE = app
VERSION = 0.1.0

DEFINES += APP_VERSION=\\\"$$VERSION\\\"
DEFINES += APP_BETA

HEADERS += \
    quickwidget.hpp \
    quickwidgetsettings.hpp \
    appeventlistener.hpp

SOURCES += \
    main.cpp\
    quickwidget.cpp \
    quickwidgetsettings.cpp \
    appeventlistener.cpp

FORMS += \
    quickwidgetsettings.ui

OTHER_FILES += \
    data/quick-widgets.desktop \
    data/quick-widgets-widget.desktop \
    data/quick-widgets

#    data/quick-widgets.png
#    data/quick-widgets-48x48.png

CONFIG += link_pkgconfig
PKGCONFIG += hildon-extras-1 q-extras

# All generated files should go to the same directory
OBJECTS_DIR = build
MOC_DIR = build
UI_DIR = build
DESTDIR = build

# Targets for debian source and binary package creation
debian-src.commands = dpkg-buildpackage -S -sa -r -us -uc -d
debian-bin.commands = dpkg-buildpackage -b -r -uc -d
debian-all.depends = debian-src debian-bin

# Clean all but Makefile
compiler_clean.commands = -$(DEL_FILE) $(TARGET)

QMAKE_EXTRA_TARGETS += debian-all debian-src debian-bin compiler_clean