+###############################################################################
+#
+# This file is part of quickdice.
+#
+# Copyright (C) 2011 Digia Plc. and/or its subsidiary(-ies).
+# Contact: Zoltan Papp <zoltan.papp@digia.com>
+#
+# This library is free software; you can redistribute it and/or modify it
+# under the terms of the GNU Lesser General Public License version 2.1 as
+# published by the Free Software Foundation.
+#
+# This library is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+# or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
+# License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public License
+# along with this library; if not, write to the Free Software Foundation, Inc.,
+# 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
+#
+###############################################################################
+
+#------------------------------------------------------------------------------
+# Common installation configuration for all projects.
+#------------------------------------------------------------------------------
+
+#------------------------------------------------------------------------------
+# setup the installation prefix
+#------------------------------------------------------------------------------
+!include( common-vars.pri ) : \
+ error( "Unable to include common-vars.pri" )
+
+INSTALL_PREFIX = /usr # default installation prefix
+
+# default prefix can be overriden by defining PREFIX when running qmake
+isEmpty( PREFIX ) {
+
+ message("====")
+ message("==== NOTE: To override the installation path run: `qmake PREFIX=/custom/path'")
+ message("==== (current installation path is `$${INSTALL_PREFIX}')")
+} else {
+
+ INSTALL_PREFIX = $${PREFIX}
+ message("====")
+ message("==== install prefix set to `$${INSTALL_PREFIX}'")
+}
+
+#------------------------------------------------------------------------------
+# default installation target for applications
+#------------------------------------------------------------------------------
+contains( TEMPLATE, app ) {
+
+ target.path = $${INSTALL_PREFIX}/bin
+ INSTALLS += target
+ message("====")
+ message("==== INSTALLS += target")
+}
+
+#------------------------------------------------------------------------------
+# default installation target for libraries
+#------------------------------------------------------------------------------
+contains( TEMPLATE, lib ) {
+
+ target.path = $${INSTALL_PREFIX}/lib
+ INSTALLS += target
+ message("====")
+ message("==== INSTALLS += target")
+}
+
+#-----------------------------------------------------------------------------
+# target for header files
+#-----------------------------------------------------------------------------
+!isEmpty( headers.files ) {
+
+ headers.path = $${INSTALL_PREFIX}/include/$${PROJECT_FULL_NAME}
+ INSTALLS += headers
+ message("====")
+ message("==== INSTALLS += headers")
+} else {
+
+ message("====")
+ message("==== NOTE: Remember to add your API headers into `headers.files' for installation!")
+}
+
+#------------------------------------------------------------------------------
+# End of File
+#------------------------------------------------------------------------------
+