git.maemo.org Git - sbrightapplet/blob - configure.ac

   1 AC_INIT(m4_esyscmd([dpkg-parsechangelog | grep ^Source:.* | cut -d ' ' -f 2 | tr -d '\n']), m4_esyscmd([dpkg-parsechangelog | grep ^Version:.* | cut -d ' ' -f 2 | tr -d '\n']), m4_esyscmd([dpkg-parsechangelog | grep ^Maintainer:.* | awk '{print $2 " "$3}' | tr -d '\n']))
   2 AC_CONFIG_SRCDIR([src/simple-brightness-applet.c])
   3 AM_INIT_AUTOMAKE([foreign dist-tarZ])
   4 AC_CONFIG_HEADERS([config.h])
   5
   6 AM_MAINTAINER_MODE
   7
   8 AC_PROG_CC
   9 AM_PROG_CC_C_O
  10 AC_HEADER_STDC
  11 AM_PATH_GLIB_2_0([2.16.0])
  12 AM_PATH_GTK_2_0([2.14.7])
  13 AC_PROG_INSTALL
  14 AC_DISABLE_STATIC
  15 AM_PROG_LIBTOOL
  16 AC_PREFIX_DEFAULT(/usr)
  17
  18 # AC_PREFIX_DEFAULT does not get expanded until too late so we need to do this to use prefix in this script --conny
  19 if test "x$prefix" = "xNONE" ; then
  20         prefix='/usr'
  21 fi
  22
  23 PKG_CHECK_MODULES(BRIGHTNESS, hildon-1 libhildondesktop-1 gtk+-2.0 glib-2.0 gobject-2.0 gconf-2.0 libosso)
  24 AC_SUBST(BRIGHTNESS_CFLAGS)
  25 AC_SUBST(BRIGHTNESS_LIBS)
  26
  27 PKG_CHECK_MODULES([OSSOSETTINGS], [osso-af-settings])
  28
  29 HILDON_HOME_DESKTOP_DIR=`pkg-config libhildondesktop-1 --variable=hildonstatusmenudesktopentrydir`
  30 AC_SUBST(HILDON_HOME_DESKTOP_DIR)
  31
  32 HILDON_DESKTOP_LIB_DIR=`pkg-config libhildondesktop-1 --variable=hildondesktoplibdir`
  33 AC_SUBST(HILDON_DESKTOP_LIB_DIR)
  34
  35 LOCALEDIR=`$PKG_CONFIG osso-af-settings --variable=localedir`
  36 AC_SUBST([LOCALEDIR])
  37 AC_DEFINE_UNQUOTED([LOCALEDIR], ["$LOCALEDIR"], [LOCALEDIR])
  38
  39 AH_TEMPLATE([GETTEXT_PACKAGE], [NAME])
  40 GETTEXT_PACKAGE=m4_esyscmd([dpkg-parsechangelog | sed -n 's/Source: //p' | tr -d '\n'])
  41 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"], [Gettext package])
  42 AC_SUBST([GETTEXT_PACKAGE])
  43 AC_PROG_INTLTOOL([0.40.0],[no-xml])
  44 AM_GLIB_GNU_GETTEXT
  45
  46 AC_OUTPUT([Makefile po/Makefile.in src/Makefile data/Makefile])