git.maemo.org Git - secretnotes/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-05-10T11:29:23
   3 # -------------------------------------------------
   4 TARGET = secretnotes
   5 TEMPLATE = app
   6 CONFIG += link_pkgconfig
   7 PKGCONFIG += openssl
   8 SOURCES += main.cpp \
   9     mainwindow.cpp \
  10     passworddialog.cpp
  11 HEADERS += mainwindow.h \
  12     passworddialog.h
  13 FORMS += mainwindow.ui \
  14     passworddialog.ui
  15 TRANSLATIONS = secretnotes_pl.ts
  16
  17 unix {
  18         #VARIABLES
  19         isEmpty(PREFIX) {
  20                 PREFIX = /opt/usr
  21         }
  22         BINDIR = $$PREFIX/bin
  23         DATADIR =$$PREFIX/share
  24         DOCUMENTS = MyDocs/.documents
  25
  26         DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\" PREFIX=$$PREFIX DOCUMENTS=$$DOCUMENTS
  27
  28         #MAKE INSTALL
  29
  30         INSTALLS += target desktop translations icon48 icon64
  31
  32         target.path =$$BINDIR
  33
  34         desktop.path = /usr/share/applications/hildon
  35         desktop.files += ../data/$${TARGET}.desktop
  36
  37         translations.path = $${DATADIR}/secretnotes
  38         translations.files += $${TARGET}_*.qm
  39
  40         icon48.path = /usr/share/icons/hicolor/48x48/apps
  41         icon48.files = ../data/48x48/$${TARGET}.png
  42
  43         icon64.path = /usr/share/icons/hicolor/64x64/apps
  44         icon64.files = ../data/64x64/$${TARGET}.png
  45 }
  46