# -------------------------------------------------
# Project created by QtCreator 2010-05-10T11:29:23
# -------------------------------------------------
TARGET = secretnotes
TEMPLATE = app
CONFIG += link_pkgconfig
PKGCONFIG += openssl
SOURCES += main.cpp \
    mainwindow.cpp \
    passworddialog.cpp
HEADERS += mainwindow.h \
    passworddialog.h
FORMS += mainwindow.ui \
    passworddialog.ui
TRANSLATIONS = secretnotes_pl.ts

unix {
	#VARIABLES
	isEmpty(PREFIX) {
		PREFIX = /opt/usr
	}
	BINDIR = $$PREFIX/bin
	DATADIR =$$PREFIX/share
	DOCUMENTS = MyDocs/.documents

	DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\" PREFIX=$$PREFIX DOCUMENTS=$$DOCUMENTS

	#MAKE INSTALL

	INSTALLS += target desktop translations icon48 icon64

	target.path =$$BINDIR

	desktop.path = /usr/share/applications/hildon
	desktop.files += ../data/$${TARGET}.desktop

	translations.path = $${DATADIR}/secretnotes
	translations.files += $${TARGET}_*.qm

	icon48.path = /usr/share/icons/hicolor/48x48/apps
	icon48.files = ../data/48x48/$${TARGET}.png

	icon64.path = /usr/share/icons/hicolor/64x64/apps
	icon64.files = ../data/64x64/$${TARGET}.png
}