git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     ui/indicatorbutton.cpp \
  58     routing/routingservice.cpp \
  59     routing/routesegment.cpp \
  60     routing/route.cpp \
  61     routing/location.cpp \
  62     map/maprouteitem.cpp \
  63     coordinates/scenecoordinate.cpp \
  64     coordinates/geocoordinate.cpp \
  65     ui/listview.cpp \
  66     ui/listitem.cpp \
  67     ui/listitemdelegate.cpp \
  68     ui/friendlistitemdelegate.cpp \
  69     ui/searchdialog.cpp \
  70     ui/indicatorbuttonpanel.cpp\
  71     routing/geocodingservice.cpp
  72 HEADERS += application.h \
  73     common.h \
  74     engine/engine.h \
  75     facebookservice/facebookauthentication.h \
  76     facebookservice/facebookcommon.h \
  77     facebookservice/facebookcredentials.h \
  78     gps/gpscommon.h \
  79     gps/gpsposition.h \
  80     map/baselocationitem.h \
  81     map/friendgroupitem.h \
  82     map/frienditemshandler.h \
  83     map/friendlocationitem.h \
  84     map/gpslocationitem.h \
  85     map/mapcommon.h \
  86     map/mapengine.h \
  87     map/mapfetcher.h \
  88     map/mapscene.h \
  89     map/mapscroller.h \
  90     map/maptile.h \
  91     map/maptilerequest.h \
  92     map/mapview.h \
  93     map/ownlocationitem.h \
  94     network/networkaccessmanager.h \
  95     network/networkcookiejar.h \
  96     network/networkhandler.h \
  97     network/networkreply.h \
  98     situareservice/imagefetcher.h \
  99     situareservice/situarecommon.h \
 100     situareservice/situareservice.h \
 101     ui/updatelocation/texteditautoresizer.h \
 102     ui/updatelocation/updatelocationdialog.h \
 103     ui/avatarimage.h \
 104     ui/friendlistitem.h \
 105     ui/friendlistpanel.h \
 106     ui/imagebutton.h \
 107     ui/logindialog.h \
 108     ui/mainwindow.h \
 109     ui/mapscale.h \
 110     ui/panelcommon.h \
 111     ui/panelsidebar.h \
 112     ui/panelsliderbar.h \
 113     ui/settingsdialog.h \
 114     ui/userinfo.h \
 115     ui/userinfopanel.h \
 116     ui/sidepanel.h \
 117     ui/sidepanelbase.h \
 118     ui/zoombutton.h \
 119     ui/zoombuttonpanel.h \
 120     user/user.h \
 121     ui/fullscreenbutton.h \
 122     engine/mce.h \
 123     ui/indicatorbutton.h \
 124     routing/routingservice.h \
 125     routing/routingcommon.h \
 126     routing/routesegment.h \
 127     routing/route.h \
 128     routing/location.h \
 129     map/maprouteitem.h \
 130     map/osm.h \
 131     coordinates/scenecoordinate.h \
 132     coordinates/geocoordinate.h \
 133     ui/listview.h \
 134     ui/listitem.h \
 135     ui/listitemdelegate.h \
 136     ui/friendlistitemdelegate.h \
 137     ui/listcommon.h \
 138     ui/searchdialog.h \
 139     ui/indicatorbuttonpanel.h\
 140     error.h \
 141     routing/geocodingservice.h
 142 QT += network \
 143     webkit
 144
 145 DEFINES += QT_NO_DEBUG_OUTPUT
 146
 147 simulator {
 148     SOURCES += network/networkhandlerprivatestub.cpp \
 149                gps/gpspositionprivate.cpp
 150     HEADERS += network/networkhandlerprivatestub.h \
 151                gps/gpspositionprivate.h
 152     QT += maemo5
 153     CONFIG += mobility
 154     MOBILITY += location
 155 } else:maemo5 {
 156     armel {
 157         DEFINES += ARMEL
 158         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 159         SOURCES += network/networkhandlerprivate.cpp \
 160                    engine/mceprivate.cpp
 161         HEADERS += network/networkhandlerprivate.h \
 162                    engine/mceprivate.h
 163         QT += dbus xml
 164         CONFIG += icd2 qdbus
 165         SOURCES += gps/gpspositionprivateliblocation.cpp \
 166                    gps/liblocationwrapper.cpp \
 167                    gps/geopositioninfo.cpp
 168         HEADERS += gps/gpspositionprivateliblocation.h \
 169                    gps/liblocationwrapper.h \
 170                    gps/geopositioninfo.h
 171         CONFIG += link_pkgconfig
 172         PKGCONFIG += glib-2.0 liblocation mce
 173         LIBS += -llocation
 174     } else {
 175         SOURCES += gps/gpspositionprivatestub.cpp \
 176                    network/networkhandlerprivatestub.cpp \
 177                    engine/mceprivatestub.cpp
 178         HEADERS += gps/gpspositionprivatestub.h \
 179                    network/networkhandlerprivatestub.h \
 180                    engine/mceprivatestub.h
 181     }
 182
 183     QT += maemo5
 184
 185     message([QJson])
 186     message(Make sure you have QJson development headers installed)
 187     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 188     message(to Scratchbox's sources.list in /etc/apt)
 189     message(run: apt-get update)
 190     message(install headers with: apt-get install libqjson-dev)
 191     message([QtMobility])
 192     message(Make sure you have QtMobility development headers installed)
 193     message(install headers with: apt-get install libqtm-dev)
 194 } else {
 195     SOURCES += gps/gpspositionprivatestub.cpp \
 196                network/networkhandlerprivatestub.cpp \
 197                engine/mceprivatestub.cpp
 198     HEADERS += gps/gpspositionprivatestub.h \
 199                network/networkhandlerprivatestub.h \
 200                engine/mceprivatestub.h
 201     message(QJson built in)
 202     message(Make sure you have QJson development headers installed)
 203     message(install headers with: sudo apt-get install libqjson-dev)
 204 }
 205
 206 # -----------------------------------------------------------------
 207 # Debian packetizing additions
 208 # -----------------------------------------------------------------
 209 unix {
 210     # VARIABLES
 211     isEmpty(PREFIX):PREFIX = /usr
 212     BINDIR = $$PREFIX/bin
 213     DATADIR = $$PREFIX/share
 214     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 215         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 216
 217     # MAKE INSTALL
 218     desktop.path = $$DATADIR/applications/hildon
 219     desktop.files += situare.desktop
 220     INSTALLS += desktop
 221     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 222     icon48.files += ../res/icon/48x48/situare.png
 223     INSTALLS += icon48
 224     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 225     icon64.files += ../res/icon/64x64/situare.png
 226     INSTALLS += icon64
 227     target.path = $$BINDIR
 228     INSTALLS += target
 229 }