git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 LIBS += -lqjson
   7 RESOURCES += ../images.qrc \
   8     ../languages.qrc
   9 TRANSLATIONS += ../res/languages/situare_fi.ts
  10 SOURCES += main.cpp \
  11     application.cpp \
  12     coordinates/geocoordinate.cpp \
  13     coordinates/scenecoordinate.cpp \
  14     engine/contactmanager.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     gps/gpsposition.cpp \
  19     map/baselocationitem.cpp \
  20     map/friendgroupitem.cpp \
  21     map/frienditemshandler.cpp \
  22     map/friendlocationitem.cpp \
  23     map/gpslocationitem.cpp \
  24     map/mapengine.cpp \
  25     map/mapfetcher.cpp \
  26     map/maprouteitem.cpp \
  27     map/mapscene.cpp \
  28     map/mapscroller.cpp \
  29     map/maptile.cpp \
  30     map/maptilerequest.cpp \
  31     map/mapview.cpp \
  32     map/ownlocationitem.cpp \
  33     network/networkaccessmanager.cpp \
  34     network/networkcookiejar.cpp \
  35     network/networkhandler.cpp \
  36     network/networkreply.cpp \
  37     routing/geocodingservice.cpp \
  38     routing/location.cpp \
  39     routing/route.cpp \
  40     routing/routesegment.cpp \
  41     routing/routingservice.cpp \
  42     situareservice/imagefetcher.cpp \
  43     situareservice/situareservice.cpp \
  44     ui/updatelocation/texteditautoresizer.cpp \
  45     ui/updatelocation/updatelocationdialog.cpp \
  46     ui/avatarimage.cpp \
  47     ui/extendedlistitem.cpp \
  48     ui/extendedlistitemdelegate.cpp \
  49     ui/extendedlistitemstore.cpp \
  50     ui/friendlistitem.cpp \
  51     ui/friendlistitemdelegate.cpp \
  52     ui/friendlistpanel.cpp \
  53     ui/friendlistview.cpp \
  54     ui/fullscreenbutton.cpp \
  55     ui/imagebutton.cpp \
  56     ui/indicatorbutton.cpp \
  57     ui/listitem.cpp \
  58     ui/listitemdelegate.cpp \
  59     ui/listview.cpp \
  60     ui/locationlistitem.cpp \
  61     ui/locationlistview.cpp \
  62     ui/indicatorbuttonpanel.cpp \
  63     ui/locationsearchpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/panelbar.cpp \
  68     ui/panelbase.cpp \
  69     ui/panelcontentstack.cpp \
  70     ui/panelcontextbuttonbar.cpp \
  71     ui/paneltab.cpp \
  72     ui/paneltabbar.cpp \
  73     ui/routingpanel.cpp \
  74     ui/routewaypointlistitem.cpp \
  75     ui/routewaypointlistview.cpp \
  76     ui/searchdialog.cpp \
  77     ui/searchhistorylistitem.cpp \
  78     ui/searchhistorylistview.cpp \
  79     ui/settingsdialog.cpp \
  80     ui/tabbedpanel.cpp \
  81     ui/textmodifier.cpp \
  82     ui/userinfo.cpp \
  83     ui/userinfopanel.cpp \
  84     ui/zoombutton.cpp \
  85     ui/zoombuttonpanel.cpp \
  86     user/user.cpp \
  87     ui/listitemcontextbuttonbar.cpp \
  88     ui/facebookloginbrowser.cpp
  89 HEADERS += application.h \
  90     common.h \
  91     coordinates/geocoordinate.h \
  92     coordinates/scenecoordinate.h \
  93     engine/contactmanager.h \
  94     engine/engine.h \
  95     engine/mce.h \
  96     error.h \
  97     facebookservice/facebookauthentication.h \
  98     facebookservice/facebookcommon.h \
  99     gps/gpscommon.h \
 100     gps/gpsposition.h \
 101     map/baselocationitem.h \
 102     map/friendgroupitem.h \
 103     map/frienditemshandler.h \
 104     map/friendlocationitem.h \
 105     map/gpslocationitem.h \
 106     map/mapcommon.h \
 107     map/mapengine.h \
 108     map/mapfetcher.h \
 109     map/maprouteitem.h \
 110     map/mapscene.h \
 111     map/mapscroller.h \
 112     map/maptile.h \
 113     map/maptilerequest.h \
 114     map/mapview.h \
 115     map/osm.h \
 116     map/ownlocationitem.h \
 117     network/networkaccessmanager.h \
 118     network/networkcookiejar.h \
 119     network/networkhandler.h \
 120     network/networkreply.h \
 121     routing/geocodingservice.h \
 122     routing/location.h \
 123     routing/route.h \
 124     routing/routesegment.h \
 125     routing/routingcommon.h \
 126     routing/routingservice.h \
 127     situareservice/imagefetcher.h \
 128     situareservice/situarecommon.h \
 129     situareservice/situareservice.h \
 130     ui/updatelocation/texteditautoresizer.h \
 131     ui/updatelocation/updatelocationdialog.h \
 132     ui/avatarimage.h \
 133     ui/extendedlistitem.h \
 134     ui/extendedlistitemdelegate.h \
 135     ui/extendedlistitemstore.h \
 136     ui/friendlistitem.h \
 137     ui/friendlistitemdelegate.h \
 138     ui/friendlistpanel.h \
 139     ui/friendlistview.h \
 140     ui/fullscreenbutton.h \
 141     ui/imagebutton.h \
 142     ui/indicatorbutton.h \
 143     ui/indicatorbuttonpanel.h \
 144     ui/listcommon.h \
 145     ui/listview.h \
 146     ui/listitem.h \
 147     ui/listitemdelegate.h \
 148     ui/logindialog.h \
 149     ui/locationlistitem.h \
 150     ui/locationlistview.h \
 151     ui/locationsearchpanel.h \
 152     ui/mainwindow.h \
 153     ui/mapscale.h \
 154     ui/panelbar.h \
 155     ui/panelbase.h \
 156     ui/panelcommon.h \
 157     ui/panelcontentstack.h \
 158     ui/panelcontextbuttonbar.h \
 159     ui/paneltab.h \
 160     ui/paneltabbar.h \
 161     ui/routingpanel.h \
 162     ui/routewaypointlistitem.h \
 163     ui/routewaypointlistview.h \
 164     ui/searchdialog.h \
 165     ui/searchhistorylistitem.h \
 166     ui/searchhistorylistview.h \
 167     ui/settingsdialog.h \
 168     ui/tabbedpanel.h \
 169     ui/textmodifier.h \
 170     ui/userinfo.h \
 171     ui/userinfopanel.h \
 172     ui/zoombutton.h \
 173     ui/zoombuttonpanel.h \
 174     user/user.h \
 175     ui/listitemcontextbuttonbar.h \
 176     ui/facebookloginbrowser.h
 177 QT += network \
 178     webkit
 179 DEFINES += QT_NO_DEBUG_OUTPUT
 180
 181 simulator {
 182     SOURCES += network/networkhandlerprivatestub.cpp \
 183                gps/gpspositionprivate.cpp \
 184                engine/contactmanagerprivatestub.cpp \
 185                engine/mceprivatestub.cpp
 186     HEADERS += network/networkhandlerprivatestub.h \
 187                gps/gpspositionprivate.h \
 188                engine/contactmanagerprivatestub.h \
 189                engine/mceprivatestub.h
 190     CONFIG += mobility
 191     MOBILITY += location
 192 } else:maemo5 {
 193     armel {
 194         DEFINES += ARMEL
 195         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 196         SOURCES += network/networkhandlerprivate.cpp \
 197                    engine/mceprivate.cpp
 198         HEADERS += network/networkhandlerprivate.h \
 199                    engine/mceprivate.h
 200         QT += dbus xml
 201         CONFIG += icd2 qdbus
 202         SOURCES += gps/gpspositionprivateliblocation.cpp \
 203                    gps/liblocationwrapper.cpp \
 204                    gps/geopositioninfo.cpp
 205         HEADERS += gps/gpspositionprivateliblocation.h \
 206                    gps/liblocationwrapper.h \
 207                    gps/geopositioninfo.h
 208         CONFIG += link_pkgconfig
 209         PKGCONFIG += glib-2.0 liblocation mce gtk+-2.0 libosso-abook-1.0
 210         LIBS += -llocation
 211         SOURCES += engine/contactmanagerprivate.cpp \
 212                    ui/ossoabookdialog.cpp
 213         HEADERS += engine/contactmanagerprivate.h \
 214                    ui/ossoabookdialog.h
 215         CONFIG += mobility
 216         MOBILITY += contacts
 217     } else {
 218         SOURCES += gps/gpspositionprivatestub.cpp \
 219                    network/networkhandlerprivatestub.cpp \
 220                    engine/mceprivatestub.cpp
 221         HEADERS += gps/gpspositionprivatestub.h \
 222                    network/networkhandlerprivatestub.h \
 223                    engine/mceprivatestub.h
 224         SOURCES += engine/contactmanagerprivatestub.cpp
 225         HEADERS += engine/contactmanagerprivatestub.h
 226     }
 227
 228     QT += maemo5
 229
 230     message([QJson])
 231     message(Make sure you have QJson development headers installed)
 232     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 233     message(to Scratchbox's sources.list in /etc/apt)
 234     message(run: apt-get update)
 235     message(install headers with: apt-get install libqjson-dev)
 236     message([QtMobility])
 237     message(Make sure you have QtMobility development headers installed)
 238     message(install headers with: apt-get install libqtm-dev)
 239 } else {
 240     SOURCES += gps/gpspositionprivatestub.cpp \
 241                network/networkhandlerprivatestub.cpp \
 242                engine/mceprivatestub.cpp
 243     HEADERS += gps/gpspositionprivatestub.h \
 244                network/networkhandlerprivatestub.h \
 245                engine/mceprivatestub.h
 246     SOURCES += engine/contactmanagerprivatestub.cpp
 247     HEADERS += engine/contactmanagerprivatestub.h
 248     message(QJson built in)
 249     message(Make sure you have QJson development headers installed)
 250     message(install headers with: sudo apt-get install libqjson-dev)
 251 }
 252
 253 # -----------------------------------------------------------------
 254 # Debian packetizing additions
 255 # -----------------------------------------------------------------
 256 unix {
 257     # VARIABLES
 258     isEmpty(PREFIX):PREFIX = /usr
 259     BINDIR = $$PREFIX/bin
 260     DATADIR = $$PREFIX/share
 261     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 262         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 263
 264     # MAKE INSTALL
 265     desktop.path = $$DATADIR/applications/hildon
 266     desktop.files += situare.desktop
 267     INSTALLS += desktop
 268     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 269     icon48.files += ../res/icon/48x48/situare.png
 270     INSTALLS += icon48
 271     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 272     icon64.files += ../res/icon/64x64/situare.png
 273     INSTALLS += icon64
 274     target.path = $$BINDIR
 275     INSTALLS += target
 276 }