git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 LIBS += -lqjson
   7 RESOURCES += ../images.qrc \
   8     ../languages.qrc
   9 TRANSLATIONS += ../res/languages/situare_fi.ts
  10 SOURCES += main.cpp \
  11     application.cpp \
  12     coordinates/geocoordinate.cpp \
  13     coordinates/scenecoordinate.cpp \
  14     engine/contactmanager.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     gps/gpsposition.cpp \
  19     map/baselocationitem.cpp \
  20     map/friendgroupitem.cpp \
  21     map/frienditemshandler.cpp \
  22     map/friendlocationitem.cpp \
  23     map/gpslocationitem.cpp \
  24     map/mapengine.cpp \
  25     map/mapfetcher.cpp \
  26     map/maprouteitem.cpp \
  27     map/mapscene.cpp \
  28     map/mapscroller.cpp \
  29     map/maptile.cpp \
  30     map/maptilerequest.cpp \
  31     map/mapview.cpp \
  32     map/ownlocationitem.cpp \
  33     network/networkaccessmanager.cpp \
  34     network/networkcookiejar.cpp \
  35     network/networkhandler.cpp \
  36     network/networkreply.cpp \
  37     routing/geocodingservice.cpp \
  38     routing/location.cpp \
  39     routing/route.cpp \
  40     routing/routesegment.cpp \
  41     routing/routingservice.cpp \
  42     situareservice/imagefetcher.cpp \
  43     situareservice/situareservice.cpp \
  44     ui/updatelocation/texteditautoresizer.cpp \
  45     ui/updatelocation/updatelocationdialog.cpp \
  46     ui/avatarimage.cpp \
  47     ui/extendedlistitem.cpp \
  48     ui/extendedlistitemdelegate.cpp \
  49     ui/extendedlistitemstore.cpp \
  50     ui/friendlistitem.cpp \
  51     ui/friendlistitemdelegate.cpp \
  52     ui/friendlistpanel.cpp \
  53     ui/friendlistview.cpp \
  54     ui/fullscreenbutton.cpp \
  55     ui/imagebutton.cpp \
  56     ui/indicatorbutton.cpp \
  57     ui/listitem.cpp \
  58     ui/listitemdelegate.cpp \
  59     ui/listview.cpp \
  60     ui/locationlistitem.cpp \
  61     ui/locationlistview.cpp \
  62     ui/indicatorbuttonpanel.cpp \
  63     ui/locationsearchpanel.cpp \
  64     ui/mainwindow.cpp \
  65     ui/mapscale.cpp \
  66     ui/panelbar.cpp \
  67     ui/panelbase.cpp \
  68     ui/panelcontentstack.cpp \
  69     ui/panelcontextbuttonbar.cpp \
  70     ui/paneltab.cpp \
  71     ui/paneltabbar.cpp \
  72     ui/routingpanel.cpp \
  73     ui/routewaypointlistitem.cpp \
  74     ui/routewaypointlistview.cpp \
  75     ui/searchdialog.cpp \
  76     ui/searchhistorylistitem.cpp \
  77     ui/searchhistorylistview.cpp \
  78     ui/settingsdialog.cpp \
  79     ui/tabbedpanel.cpp \
  80     ui/textmodifier.cpp \
  81     ui/userinfo.cpp \
  82     ui/userinfopanel.cpp \
  83     ui/zoombutton.cpp \
  84     ui/zoombuttonpanel.cpp \
  85     user/user.cpp \
  86     ui/listitemcontextbuttonbar.cpp \
  87     engine/updatelocation.cpp
  88 HEADERS += application.h \
  89     common.h \
  90     coordinates/geocoordinate.h \
  91     coordinates/scenecoordinate.h \
  92     engine/contactmanager.h \
  93     engine/engine.h \
  94     engine/mce.h \
  95     error.h \
  96     facebookservice/facebookauthentication.h \
  97     gps/gpscommon.h \
  98     gps/gpsposition.h \
  99     map/baselocationitem.h \
 100     map/friendgroupitem.h \
 101     map/frienditemshandler.h \
 102     map/friendlocationitem.h \
 103     map/gpslocationitem.h \
 104     map/mapcommon.h \
 105     map/mapengine.h \
 106     map/mapfetcher.h \
 107     map/maprouteitem.h \
 108     map/mapscene.h \
 109     map/mapscroller.h \
 110     map/maptile.h \
 111     map/maptilerequest.h \
 112     map/mapview.h \
 113     map/osm.h \
 114     map/ownlocationitem.h \
 115     network/networkaccessmanager.h \
 116     network/networkcookiejar.h \
 117     network/networkhandler.h \
 118     network/networkreply.h \
 119     routing/geocodingservice.h \
 120     routing/location.h \
 121     routing/route.h \
 122     routing/routesegment.h \
 123     routing/routingcommon.h \
 124     routing/routingservice.h \
 125     situareservice/imagefetcher.h \
 126     situareservice/situarecommon.h \
 127     situareservice/situareservice.h \
 128     ui/updatelocation/texteditautoresizer.h \
 129     ui/updatelocation/updatelocationdialog.h \
 130     ui/avatarimage.h \
 131     ui/extendedlistitem.h \
 132     ui/extendedlistitemdelegate.h \
 133     ui/extendedlistitemstore.h \
 134     ui/friendlistitem.h \
 135     ui/friendlistitemdelegate.h \
 136     ui/friendlistpanel.h \
 137     ui/friendlistview.h \
 138     ui/fullscreenbutton.h \
 139     ui/imagebutton.h \
 140     ui/indicatorbutton.h \
 141     ui/indicatorbuttonpanel.h \
 142     ui/listcommon.h \
 143     ui/listview.h \
 144     ui/listitem.h \
 145     ui/listitemdelegate.h \
 146     ui/locationlistitem.h \
 147     ui/locationlistview.h \
 148     ui/locationsearchpanel.h \
 149     ui/mainwindow.h \
 150     ui/mapscale.h \
 151     ui/panelbar.h \
 152     ui/panelbase.h \
 153     ui/panelcommon.h \
 154     ui/panelcontentstack.h \
 155     ui/panelcontextbuttonbar.h \
 156     ui/paneltab.h \
 157     ui/paneltabbar.h \
 158     ui/routingpanel.h \
 159     ui/routewaypointlistitem.h \
 160     ui/routewaypointlistview.h \
 161     ui/searchdialog.h \
 162     ui/searchhistorylistitem.h \
 163     ui/searchhistorylistview.h \
 164     ui/settingsdialog.h \
 165     ui/tabbedpanel.h \
 166     ui/textmodifier.h \
 167     ui/userinfo.h \
 168     ui/userinfopanel.h \
 169     ui/zoombutton.h \
 170     ui/zoombuttonpanel.h \
 171     user/user.h \
 172     ui/listitemcontextbuttonbar.h \
 173     engine/updatelocation.h
 174 QT += network \
 175     webkit
 176 DEFINES += QT_NO_DEBUG_OUTPUT
 177
 178 simulator {
 179     SOURCES += network/networkhandlerprivatestub.cpp \
 180                gps/gpspositionprivate.cpp \
 181                engine/contactmanagerprivatestub.cpp \
 182                engine/mceprivatestub.cpp
 183     HEADERS += network/networkhandlerprivatestub.h \
 184                gps/gpspositionprivate.h \
 185                engine/contactmanagerprivatestub.h \
 186                engine/mceprivatestub.h
 187     CONFIG += mobility
 188     MOBILITY += location
 189 } else:maemo5 {
 190     armel {
 191         DEFINES += ARMEL
 192         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 193         SOURCES += network/networkhandlerprivate.cpp \
 194                    engine/mceprivate.cpp
 195         HEADERS += network/networkhandlerprivate.h \
 196                    engine/mceprivate.h
 197         QT += dbus xml
 198         CONFIG += icd2 qdbus
 199         SOURCES += gps/gpspositionprivateliblocation.cpp \
 200                    gps/liblocationwrapper.cpp \
 201                    gps/geopositioninfo.cpp
 202         HEADERS += gps/gpspositionprivateliblocation.h \
 203                    gps/liblocationwrapper.h \
 204                    gps/geopositioninfo.h
 205         CONFIG += link_pkgconfig
 206         PKGCONFIG += glib-2.0 liblocation mce gtk+-2.0 libosso-abook-1.0
 207         LIBS += -llocation
 208         SOURCES += engine/contactmanagerprivate.cpp \
 209                    ui/ossoabookdialog.cpp
 210         HEADERS += engine/contactmanagerprivate.h \
 211                    ui/ossoabookdialog.h
 212         CONFIG += mobility
 213         MOBILITY += contacts
 214     } else {
 215         SOURCES += gps/gpspositionprivatestub.cpp \
 216                    network/networkhandlerprivatestub.cpp \
 217                    engine/mceprivatestub.cpp
 218         HEADERS += gps/gpspositionprivatestub.h \
 219                    network/networkhandlerprivatestub.h \
 220                    engine/mceprivatestub.h
 221         SOURCES += engine/contactmanagerprivatestub.cpp
 222         HEADERS += engine/contactmanagerprivatestub.h
 223     }
 224
 225     QT += maemo5
 226
 227     message([QJson])
 228     message(Make sure you have QJson development headers installed)
 229     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 230     message(to Scratchbox's sources.list in /etc/apt)
 231     message(run: apt-get update)
 232     message(install headers with: apt-get install libqjson-dev)
 233     message([QtMobility])
 234     message(Make sure you have QtMobility development headers installed)
 235     message(install headers with: apt-get install libqtm-dev)
 236 } else {
 237     SOURCES += gps/gpspositionprivatestub.cpp \
 238                network/networkhandlerprivatestub.cpp \
 239                engine/mceprivatestub.cpp
 240     HEADERS += gps/gpspositionprivatestub.h \
 241                network/networkhandlerprivatestub.h \
 242                engine/mceprivatestub.h
 243     SOURCES += engine/contactmanagerprivatestub.cpp
 244     HEADERS += engine/contactmanagerprivatestub.h
 245     message(QJson built in)
 246     message(Make sure you have QJson development headers installed)
 247     message(install headers with: sudo apt-get install libqjson-dev)
 248 }
 249
 250 # -----------------------------------------------------------------
 251 # Debian packetizing additions
 252 # -----------------------------------------------------------------
 253 unix {
 254     # VARIABLES
 255     isEmpty(PREFIX):PREFIX = /usr
 256     BINDIR = $$PREFIX/bin
 257     DATADIR = $$PREFIX/share
 258     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 259         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 260
 261     # MAKE INSTALL
 262     desktop.path = $$DATADIR/applications/hildon
 263     desktop.files += situare.desktop
 264     INSTALLS += desktop
 265     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 266     icon48.files += ../res/icon/48x48/situare.png
 267     INSTALLS += icon48
 268     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 269     icon64.files += ../res/icon/64x64/situare.png
 270     INSTALLS += icon64
 271     target.path = $$BINDIR
 272     INSTALLS += target
 273 }