#-------------------------------------------------
#
# Project created by QtCreator 2010-06-26T11:35:08
#
#-------------------------------------------------

LANG_PATH = lang

QT       += maemo5 dbus

LIBS     += -lalarm

TARGET = timedsilencer

TEMPLATE = app


SOURCES += main.cpp\
           mainwindow.cpp \
    newalarmdlg.cpp \
    switchingeventlist.cpp \
    qmaemo5weekdayspickselector.cpp \
    qmaemo5weekdayspickwidget.cpp \
    checklistdelegate.cpp \
    eventlistdelegate.cpp

HEADERS  += mainwindow.h \
            alarmd_backend.h \
            dbus_backend.h \
            phone_profile.h \
    newalarmdlg.h \
    switchingeventlist.h \
    qmaemo5weekdayspickselector.h \
    qmaemo5weekdayspickwidget.h \
    checklistdelegate.h \
    profileevent.h \
    eventlistdelegate.h

# Translations
TRANSLATIONS = $$LANG_PATH/timedsilencer_en.ts \
               $$LANG_PATH/timedsilencer_fr.ts \
               $$LANG_PATH/timedsilencer_zh.ts

RESOURCES = lang.qrc

DEFINES += QT_NO_DEBUG_OUTPUT

# INSTALL
unix {
  #VARIABLES
  isEmpty(PREFIX) {
    PREFIX = /usr
  }
  BINDIR = $$PREFIX/bin
  DATADIR =$$PREFIX/share

  DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"

  #MAKE INSTALL

  INSTALLS += target desktop iconxpm icon26 icon48 icon64

  target.path =$$BINDIR

  desktop.path = $$DATADIR/applications/hildon
  desktop.files += desktop/$${TARGET}.desktop

  iconxpm.path = $$DATADIR/pixmap
  iconxpm.files += ico/xpm/$${TARGET}.xpm

  icon26.path = $$DATADIR/icons/hicolor/26x26/apps
  icon26.files += ico/26x26/$${TARGET}.png

  icon48.path = $$DATADIR/icons/hicolor/48x48/apps
  icon48.files += ico/48x48/$${TARGET}.png

  icon64.path = $$DATADIR/icons/hicolor/64x64/apps
  icon64.files += ico/64x64/$${TARGET}.png
}