TEMPLATE = subdirs
CONFIG += ordered
SUBDIRS  += vicar-lib
SUBDIRS  += vicar-daemon

contains(MEEGO_EDITION,harmattan){
    SUBDIRS  += vicar-config-qml
}
else{
    SUBDIRS  += vicar-config
}

SUBDIRS  += vicar-telepathy
SUBDIRS  += vicar-utils

#MAKE INSTALL

INSTALLS += desktop dbus_service tp_connmanager rtcom_profile icon26 icon32 icon48 icon64 appicon

dbus_service.path = /usr/share/dbus-1/services
dbus_service.files = data/dbus/org.maemo.vicar.service
dbus_service.files += data/dbus/org.freedesktop.Telepathy.ConnectionManager.vicar.service

tp_connmanager.path = /usr/share/telepathy/managers
tp_connmanager.files = data/telepathy/vicar.manager

rtcom_profile.path = /usr/share/osso-rtcom
rtcom_profile.files = data/telepathy/vicar.profile

icon26.path = /usr/share/icons/hicolor/26x26/apps
icon26.files += data/icons/26x26/vicar_harmattan.png

icon32.path = /usr/share/icons/hicolor/32x32/apps
icon32.files += data/icons/32x32/vicar_harmattan.png

icon48.path = /usr/share/icons/hicolor/48x48/apps
icon48.files += data/icons/48x48/vicar_harmattan.png

icon64.path = /usr/share/icons/hicolor/64x64/apps
icon64.files += data/icons/64x64/vicar_harmattan.png

appicon.path = /usr/share/icons/hicolor/80x80/apps
appicon.files += data/icons/vicar_harmattan.png

contains(MEEGO_EDITION,harmattan){
#Install files required for Harmattan Accounts framework
    INSTALLS += account_provider account_service account_icon

    account_provider.path = /usr/share/accounts/providers
    account_provider.files += data/accounts/vicar.provider

    account_service.path = /usr/share/accounts/services
    account_service.files += data/accounts/vicar.service

    account_icon.path = /usr/share/themes/blanco/meegotouch/icons
    account_icon.files += data/icons/icon-m-service-vicar.png

    desktop.path = /usr/share/applications
    desktop.files += data/desktop/vicar-config-qml.desktop
}

maemo5 | exists(/usr/bin/hildon-home) {
    desktop.path = /usr/share/applications/hildon
    desktop.files += data/desktop/vicar-config.desktop
}