git.maemo.org Git - cinaest/blob - src/movie-list-menu.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListMenu : AppMenu {
  23         public MovieListStore store;
  24         public MovieFilter filter;
  25         private weak MovieListWindow movie_list_window;
  26         private Hildon.Button filter_year;
  27         private Hildon.Button filter_rating;
  28         private Hildon.Button filter_genres;
  29         private Gtk.Button poster_view;
  30         private Gtk.Button delete_movies;
  31         private Gtk.Button import_movies;
  32
  33         public signal void filter_changed ();
  34
  35         public MovieListMenu (MovieListWindow window) {
  36                 movie_list_window = window;
  37         }
  38
  39         construct {
  40                 // Add sort buttons as view menu filters
  41                 var sort_by_title = new RadioButton.with_label (null, _("ABC"));
  42                 var sort_by_year = new RadioButton.with_label_from_widget (sort_by_title, _("Year"));
  43                 var sort_by_rating = new RadioButton.with_label_from_widget (sort_by_title, _("Rating"));
  44
  45                 // Draw them as toggle buttons, not as radio buttons
  46                 sort_by_title.set_mode (false);
  47                 sort_by_year.set_mode (false);
  48                 sort_by_rating.set_mode (false);
  49
  50                 // TODO - get this from GConf
  51                 sort_by_title.set_active (true);
  52
  53                 // Connect signals
  54                 sort_by_title.toggled.connect (button => {
  55                         if (button.get_active ())
  56                                 store.set_sort_column_id (MovieListStore.Columns.TITLE, Gtk.SortType.ASCENDING);
  57                 });
  58                 sort_by_year.toggled.connect (button => {
  59                         if (button.get_active ())
  60                                 store.set_sort_column_id (MovieListStore.Columns.YEAR, Gtk.SortType.DESCENDING);
  61                 });
  62                 sort_by_rating.toggled.connect (button => {
  63                         if (button.get_active ())
  64                                 store.set_sort_column_id (MovieListStore.Columns.RATING, Gtk.SortType.DESCENDING);
  65                 });
  66
  67                 add_filter (sort_by_title);
  68                 add_filter (sort_by_year);
  69                 add_filter (sort_by_rating);
  70
  71                 // Add view menu buttons
  72                 filter_year = new Hildon.Button.with_text (SizeType.FINGER_HEIGHT, ButtonArrangement.VERTICAL, _("Filter by year"), _("Off"));
  73                 filter_rating = new Hildon.Button.with_text (SizeType.FINGER_HEIGHT, ButtonArrangement.VERTICAL, _("Filter by rating"), _("Off"));
  74                 filter_genres = new Hildon.Button.with_text (SizeType.FINGER_HEIGHT, ButtonArrangement.VERTICAL, _("Filter by genres"), _("Off"));
  75                 poster_view = new Gtk.Button.with_label (_("Poster view"));
  76                 delete_movies = new Gtk.Button.with_label (_("Delete movies"));
  77                 import_movies = new Gtk.Button.with_label (_("Import movies"));
  78                 var settings = new Gtk.Button.with_label (_("Settings"));
  79
  80                 filter_year.set_style (ButtonStyle.PICKER);
  81                 filter_rating.set_style (ButtonStyle.PICKER);
  82                 filter_genres.set_style (ButtonStyle.PICKER);
  83
  84                 // Connect signals
  85                 filter_year.clicked.connect (on_filter_year_clicked);
  86                 filter_rating.clicked.connect (on_filter_rating_clicked);
  87                 filter_genres.clicked.connect (on_filter_genres_clicked);
  88                 poster_view.clicked.connect (on_poster_view_clicked);
  89                 delete_movies.clicked.connect (() => { movie_list_window.on_delete_movies_clicked (); });
  90                 import_movies.clicked.connect (on_import_movies_clicked);
  91                 settings.clicked.connect (on_settings_clicked);
  92
  93                 append (filter_year);
  94                 append (filter_rating);
  95                 append (filter_genres);
  96                 append (poster_view);
  97                 append (import_movies);
  98                 append (delete_movies);
  99                 append (settings);
 100
 101                 show_all ();
 102         }
 103
 104         public MovieSource source {
 105                 set {
 106                         if (SourceFlags.EDITABLE in value.get_flags ()) {
 107                                 delete_movies.show ();
 108                                 import_movies.show ();
 109                         } else {
 110                                 delete_movies.hide ();
 111                                 import_movies.hide ();
 112                         }
 113                 }
 114         }
 115
 116         public void on_filter_year_clicked () {
 117                 var dialog = new PickerDialog (movie_list_window);
 118                 dialog.set_title (_("Filter by year"));
 119
 120                 var year_store = new ListStore (1, typeof (string));
 121                 TreeIter iter;
 122                 for (int i = 0; i < 128; i++) {
 123                         year_store.append (out iter);
 124                         year_store.set_value (iter, 0, "%d".printf (1888 + i));
 125                 }
 126
 127                 var selector = new TouchSelector ();
 128                 selector.append_text_column (year_store, true);
 129                 selector.append_text_column (year_store, true);
 130                 if (filter.year_min > 1888 && filter.year_min < 2015) {
 131                         selector.set_active (0, filter.year_min - 1888);
 132                 } else {
 133                         selector.set_active (0, 0);
 134                 }
 135                 if (filter.year_max > 1888 && filter.year_max < 2015) {
 136                         selector.set_active (1, filter.year_max - 1888);
 137                 } else {
 138                         selector.set_active (1, 127);
 139                 }
 140                 selector.center_on_selected ();
 141                 dialog.set_selector (selector);
 142
 143                 var res = dialog.run ();
 144                 if (res == ResponseType.OK) {
 145                         filter.year_min = 1888 + selector.get_active (0);
 146                         if (filter.year_min <= 1888)
 147                                 filter.year_min = 0;
 148                         filter.year_max = 1888 + selector.get_active (1);
 149                         if (filter.year_max >= 2015)
 150                                 filter.year_max = 0;
 151
 152                         if (filter.year_min == 0 && filter.year_max == 0)
 153                                 filter_year.set_value (_("Off"));
 154                         else if (filter.year_min == 0)
 155                                 filter_year.set_value (_("Until %d").printf (filter.year_max));
 156                         else if (filter.year_max == 0)
 157                                 filter_year.set_value (_("Since %d").printf (filter.year_min));
 158                         else if (filter.year_min == filter.year_max)
 159                                 filter_year.set_value ("%d".printf (filter.year_min));
 160                         else
 161                                 filter_year.set_value ("%d - %d".printf (filter.year_min, filter.year_max));
 162
 163                         filter_changed ();
 164                 }
 165                 dialog.destroy ();
 166         }
 167
 168         public void on_filter_rating_clicked () {
 169                 var dialog = new PickerDialog (movie_list_window);
 170                 dialog.set_title (_("Filter by rating"));
 171
 172                 var selector = new TouchSelector.text ();
 173                 for (int i = 0; i < 10; i++) {
 174                         selector.append_text ("%d.0".printf (9 - i));
 175                 }
 176                 selector.set_active (0, 9 - (filter.rating_min / 10));
 177                 dialog.set_selector (selector);
 178
 179                 var res = dialog.run ();
 180                 if (res == ResponseType.OK) {
 181                         filter.rating_min = (9 - selector.get_active (0)) * 10;
 182
 183                         if (filter.rating_min == 0)
 184                                 filter_rating.set_value (_("Off"));
 185                         else
 186                                 filter_rating.set_value (_("At least %d.0").printf (filter.rating_min / 10));
 187
 188                         filter_changed ();
 189                 }
 190                 dialog.destroy ();
 191         }
 192
 193         public void on_filter_genres_clicked () {
 194                 var dialog = new GenreFilterDialog (movie_list_window);
 195                 string s;
 196
 197                 var res = dialog.run (filter);
 198
 199                 if (res == ResponseType.OK) {
 200                         s = filter.genres.to_string ();
 201                         if (s != null)
 202                                 filter_genres.set_value (s);
 203                         else
 204                                 filter_genres.set_value (_("Off"));
 205
 206                         filter_changed ();
 207                 }
 208         }
 209
 210         public void on_poster_view_clicked (Gtk.Button button) {
 211                 var poster_mode = movie_list_window.get_movie_list_view ().poster_mode;
 212                 movie_list_window.get_movie_list_view ().poster_mode = !poster_mode;
 213                 poster_view.set_label (poster_mode ? _("Poster view") : _("List view"));
 214         }
 215
 216         public void on_import_movies_clicked (Gtk.Button button) {
 217                 var dialog = new Gtk.Dialog ();
 218                 dialog.set_transient_for (movie_list_window);
 219                 dialog.set_title (_("Import movies"));
 220 /*
 221                 // import movies or ratings from some source
 222                 for (var Plugin in CinaestProgram.plugins) {
 223                         if (plugin.can_export_ratings ()) {
 224                                 exporters++;
 225                         }
 226                 }
 227                 if (exporters > 1)
 228                         exporter = run_exporter_selection_dialog
 229 */
 230                 dialog.run ();
 231         }
 232
 233         public void on_settings_clicked (Gtk.Button button) {
 234                 var dialog = new SettingsDialog (movie_list_window);
 235
 236                 dialog.run ();
 237         }
 238 }