git.maemo.org Git - cinaest/blob - src/movie-list-store.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20
  21 public class MovieListStore : ListStore, TreeModel {
  22         public enum Columns {
  23                 TITLE,
  24                 YEAR,
  25                 RATING,
  26                 POSTER,
  27                 ICON,
  28                 MOVIE,
  29                 MARKUP,
  30                 N_COLUMNS
  31         }
  32         private GLib.Type[] types = {
  33                 typeof (string),
  34                 typeof (int),
  35                 typeof (string),
  36                 typeof (Gdk.Pixbuf),
  37                 typeof (Gdk.Pixbuf),
  38                 typeof (Movie),
  39                 typeof (string)
  40         };
  41         private GLib.Type[] base_type = {
  42                 typeof (Movie),
  43                 typeof (string), // Markup: "Title (Year)"
  44                 typeof (string)  // Rating
  45         };
  46         private Gdk.Pixbuf no_poster;
  47         private MoviePoster.Factory poster_factory;
  48         private MovieFilter filter;
  49         public bool update_running { get; set; }
  50         public string year_markup = "<span size=\"small\">[%d]</span>";
  51         private Cancellable cancellable;
  52         public Widget view;
  53
  54         public signal void search_finished (int movies);
  55
  56         private MovieSource _source;
  57         public MovieSource source {
  58                 get {
  59                         return _source;
  60                 }
  61                 set {
  62                         _source = value;
  63                 }
  64         }
  65
  66         construct {
  67                 set_column_types (base_type);
  68                 no_poster = null;
  69                 source = null;
  70                 update_running = false;
  71
  72                 poster_factory = MoviePoster.Factory.get_instance ();
  73         }
  74
  75         public void add (Movie movie, out TreeIter iter) {
  76                 TreeIter iter1;
  77                 var markup = new StringBuilder ();
  78                 markup.append (Markup.escape_text (movie.title));
  79                 if (movie.year > 0) {
  80                         markup.append (" ");
  81                         markup.append_printf (year_markup, movie.year);
  82                 }
  83
  84                 base.insert_with_values (out iter1, -1,
  85                                          0, movie,
  86                                          1, markup.str,
  87                                          2, rating_string (movie.rating));
  88
  89                 movie.notify.connect (this.on_movie_changed);
  90
  91                 iter = iter1;
  92         }
  93
  94         private string? rating_string (int rating) {
  95                 if (rating >= 0) {
  96                         return "%d.%d".printf (rating / 10,
  97                                                rating % 10);
  98                 } else {
  99                         return null;
 100                 }
 101         }
 102
 103         public new bool remove (Movie movie) {
 104                 TreeIter iter;
 105
 106                 if (get_iter_from_movie (out iter, movie)) {
 107                         movie.notify.disconnect (this.on_movie_changed);
 108                         base.remove (iter);
 109
 110                         if (SourceFlags.EDITABLE in source.get_flags ()) {
 111                                 source.delete_movie (movie);
 112                         }
 113
 114                         return true;
 115                 }
 116
 117                 return false;
 118         }
 119
 120         private void on_movie_changed (GLib.Object source, GLib.ParamSpec spec) {
 121                 var movie = (Movie) source;
 122
 123                 TreeIter iter;
 124                 if (get_iter_from_movie (out iter, movie)) {
 125                         TreePath path = get_path (iter);
 126                         base.row_changed (path, iter);
 127                 }
 128         }
 129
 130         public bool get_editable () {
 131                 return (SourceFlags.EDITABLE in source.get_flags ());
 132         }
 133
 134         public bool get_iter_from_movie (out TreeIter iter, Movie movie_a) {
 135                 if (get_iter_first (out iter)) {
 136                         do {
 137                                 Movie movie_b;
 138                                 get (iter, Columns.MOVIE, out movie_b);
 139                                 if (movie_a == movie_b)
 140                                         return true;
 141                         } while (iter_next (ref iter));
 142                 }
 143                 return false;
 144         }
 145
 146         public bool start_search (MovieFilter _filter) {
 147                 if (update_running) {
 148                         stdout.printf ("aborting search ...\n");
 149                         cancellable.cancel ();
 150                         poster_factory.clear_queue ();
 151                         return false;
 152                 }
 153                 if (cancellable == null || cancellable.is_cancelled ())
 154                         cancellable = new Cancellable ();
 155
 156                 filter = _filter;
 157                 stdout.printf ("begin search\n");
 158                 search_async.begin ();
 159                 update_running = true;
 160                 return true;
 161         }
 162
 163         // Asynchronous update method
 164         private async void search_async () {
 165                 stdout.printf ("search started: \"%s\"\n", filter.title);
 166
 167                 clear ();
 168
 169                 if (source != null) {
 170                         // FIXME - arbitrary limit
 171                         int n = yield source.get_movies (filter, receive_movie, 100, cancellable);
 172                         search_finished (n);
 173                 }
 174
 175                 update_running = false;
 176                 if (cancellable.is_cancelled ()) {
 177                         stdout.printf ("search aborted, starting new\n");
 178                         cancellable.reset ();
 179                         if (cancellable.is_cancelled ()) {
 180                                 stdout.printf ("OW WEY\n");
 181                         }
 182                         start_search (filter);
 183                 } else {
 184                         stdout.printf ("search stopped\n");
 185                 }
 186         }
 187
 188         private void receive_movie (SList<Movie> movies) {
 189                 TreeIter iter;
 190
 191                 if (cancellable.is_cancelled ())
 192                         return;
 193
 194                 view.freeze_child_notify ();
 195                 foreach (Movie movie in movies)
 196                         add (movie, out iter);
 197                 view.thaw_child_notify ();
 198         }
 199
 200         // Implement TreeModel interface
 201         public virtual GLib.Type get_column_type (int index_) {
 202                 return_val_if_fail (index_ >= 0 && index_ < Columns.N_COLUMNS, 0);
 203
 204                 return types[index_];
 205         }
 206
 207         public virtual int get_n_columns () {
 208                 return Columns.N_COLUMNS;
 209         }
 210
 211         public virtual void get_value (TreeIter iter, int column, out GLib.Value value) {
 212                 Movie movie;
 213
 214                 return_if_fail (column >= 0 && column < Columns.N_COLUMNS);
 215
 216                 // Get the Movie from our parent's storage
 217                 Value val;
 218                 base.get_value (iter, 0, out val);
 219                 movie = (Movie) val.get_object ();
 220
 221                 value.init (get_column_type (column));
 222
 223                 switch (column) {
 224                 case Columns.TITLE:
 225                         if (movie != null) {
 226                                 value.set_string (movie.title);
 227                         } else {
 228                                 value.set_string ("");
 229                         }
 230                         break;
 231
 232                 case Columns.YEAR:
 233                         if (movie != null) {
 234                                 value.set_int (movie.year);
 235                         } else {
 236                                 value.set_int (-1);
 237                         }
 238                         break;
 239
 240                 case Columns.RATING:
 241                         base.get_value (iter, 2, out value);
 242                         break;
 243
 244                 case Columns.POSTER:
 245                         if ((movie.poster != null) && (movie.poster.small != null)) {
 246                                 value.set_object (movie.poster.small);
 247                         } else {
 248                                 // FIXME
 249                                 if (no_poster == null) try {
 250                                 //      var no_pic = new Gdk.Pixbuf.from_file ("/usr/share/icons/hicolor/64x64/hildon/imageviewer_no_pic.png");
 251                                         var no_pic = new Gdk.Pixbuf.from_file ("/usr/share/icons/hicolor/64x64/hildon/general_no_thumbnail.png");
 252                                         no_poster = new Gdk.Pixbuf (Gdk.Colorspace.RGB, true, 8, Poster.SMALL_WIDTH, Poster.SMALL_HEIGHT);
 253                                         no_poster.fill (0);
 254                                         no_pic.copy_area (0, 0, no_pic.width, no_pic.height, no_poster,
 255                                                           (Poster.SMALL_WIDTH - no_pic.width) / 2, (Poster.SMALL_HEIGHT - no_pic.height) / 2);
 256                                 } catch (Error e) {
 257                                         critical ("Missing general_video icon: %s\n", e.message);
 258                                 }
 259                                 value.set_object (no_poster);
 260                         }
 261                         break;
 262
 263                 case Columns.ICON:
 264                         if ((movie.poster != null) && (movie.poster.icon != null)) {
 265                                 value.set_object (movie.poster.icon);
 266                         } else {
 267                                 value.set_object (null);
 268                         }
 269                         break;
 270
 271                 case Columns.MOVIE:
 272                         value.set_object (movie);
 273                         break;
 274
 275                 case Columns.MARKUP:
 276                         base.get_value (iter, 1, out value);
 277                         break;
 278
 279                 default:
 280                         assert_not_reached ();
 281                 }
 282         }
 283 }