git.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         private bool more_movies_available;
  28         private CellRendererText title_renderer;
  29         private CellRendererText secondary_renderer;
  30         private CellRendererText rating_renderer;
  31         private CellRendererText date_renderer;
  32
  33         public signal void movie_activated (Movie movie);
  34
  35         public MovieListView (Gtk.Window window, bool show_date = false) {
  36                 store = new MovieListStore ();
  37
  38                 Gdk.Color color;
  39                 window.ensure_style ();
  40                 if (window.style.lookup_color ("SecondaryTextColor", out color)) {
  41                         store.year_markup = "<span size=\"small\" fgcolor=\"%s\">(%%d)</span>".printf (color.to_string ());
  42                 }
  43
  44                 // Add filter wrapper
  45                 var filtered_store = new TreeModelFilter (store, null);
  46
  47                 // Add sort wrapper
  48                 sorted_store = new TreeModelSort.with_model (filtered_store);
  49
  50                 // Tree View
  51                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  52                 tree.set_headers_visible (false);
  53
  54                 add (tree);
  55
  56                 tree.set_rules_hint (true);
  57
  58                 // Tree selection object
  59                 var selection = tree.get_selection ();
  60                 selection.set_mode (SelectionMode.SINGLE);
  61
  62                 // Title column with poster
  63                 var title_column = new TreeViewColumn ();
  64                 title_column.set_title (_("Movie"));
  65                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  66                 title_column.set_reorderable (false);
  67                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  68                 title_column.set_expand (true);
  69
  70                 // Add poster icon to column
  71                 var pixbuf_renderer = new CellRendererPixbuf ();
  72                 pixbuf_renderer.width = 64;
  73                 pixbuf_renderer.xalign = 0.0f;
  74                 title_column.pack_start (pixbuf_renderer, false);
  75                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  76
  77                 // Add text to column
  78                 var vbox_renderer = new CellRendererVBox ();
  79
  80                 title_renderer = new CellRendererText ();
  81                 title_renderer.yalign = 1.0f;
  82                 title_renderer.ellipsize = Pango.EllipsizeMode.END;
  83
  84                 vbox_renderer.append (title_renderer, true);
  85
  86                 // Add secondary text to column (Genres, Director, etc.)
  87                 secondary_renderer = new CellRendererText ();
  88                 secondary_renderer.yalign = 0;
  89                 secondary_renderer.ellipsize = Pango.EllipsizeMode.END;
  90                 secondary_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
  91
  92                 vbox_renderer.append (secondary_renderer, true);
  93
  94                 title_column.pack_start (vbox_renderer, true);
  95                 title_column.set_cell_data_func (vbox_renderer, title_data_func);
  96
  97                 tree.append_column (title_column);
  98
  99                 // Sort by title
 100                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 101
 102                 // Year column
 103                 var year_column = new TreeViewColumn ();
 104                 year_column.set_title (_("Year"));
 105                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 106                 year_column.set_reorderable (false);
 107                 year_column.set_sort_order (SortType.DESCENDING);
 108                 tree.append_column (year_column);
 109
 110                 // Rating column
 111                 var rating_column = new TreeViewColumn ();
 112                 rating_column.set_title (_("Rating"));
 113                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 114                 rating_column.set_reorderable (false);
 115                 rating_column.set_sort_order (SortType.DESCENDING);
 116                 rating_column.xalign = 1.0f;
 117
 118                 vbox_renderer = new CellRendererVBox ();
 119
 120                 rating_renderer = new CellRendererText ();
 121                 rating_renderer.xalign = 1.0f;
 122                 if (show_date)
 123                         rating_renderer.yalign = 1.0f;
 124
 125                 vbox_renderer.append (rating_renderer, true);
 126
 127                 date_renderer = new CellRendererText ();
 128                 date_renderer.yalign = 0;
 129                 date_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
 130
 131                 if (show_date)
 132                         vbox_renderer.append (date_renderer, true);
 133
 134                 rating_column.pack_start (vbox_renderer, true);
 135                 rating_column.set_cell_data_func (vbox_renderer, rating_data_func);
 136
 137                 tree.append_column (rating_column);
 138
 139                 // Connect signals
 140                 get_vadjustment ().value_changed.connect (on_adjustment_value_changed);
 141                 tree.row_activated.connect (on_row_activated);
 142                 store.search_finished.connect (on_search_finished);
 143         }
 144
 145         public void set_hildon_ui_mode (UIMode mode) {
 146                 var selection = tree.get_selection ();
 147
 148                 if (mode == UIMode.NORMAL) {
 149                         selection.set_mode (SelectionMode.NONE);
 150                 }
 151                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 152                 if (mode == UIMode.EDIT) {
 153                         selection.set_mode (SelectionMode.MULTIPLE);
 154                 }
 155         }
 156
 157         public unowned TreeSelection get_selection () {
 158                 return tree.get_selection ();
 159         }
 160
 161         private Pango.AttrList get_attributes (Gtk.Window window, string font_name, string color_name) {
 162                 Pango.AttrList attr_list = new Pango.AttrList ();
 163                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), font_name, null, typeof (void));
 164                 if (style != null) {
 165                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
 166                         attr_list.insert ((owned) attr_font_desc);
 167                 }
 168                 Gdk.Color color;
 169                 window.ensure_style ();
 170                 if (window.style.lookup_color (color_name, out color)) {
 171                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
 172                         attr_list.insert ((owned) attr_color);
 173                 }
 174                 return attr_list;
 175         }
 176
 177         // TODO: after scrolling down 80% of the list, load more
 178         //       results if available.
 179         private void on_adjustment_value_changed () {
 180                 if (more_movies_available) {
 181                         var vadj = get_vadjustment ();
 182                         if (vadj.value > 0.8 * vadj.upper) {
 183                                 Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 184                                 more_movies_available = false;
 185                         }
 186                 }
 187         }
 188
 189         private void on_row_activated (TreeView tree, TreePath path, TreeViewColumn column) {
 190                 TreeModel model = tree.model;
 191                 TreeIter iter;
 192
 193                 if (model.get_iter (out iter, path)) {
 194                         Movie movie;
 195                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 196                         movie_activated (movie);
 197                 }
 198         }
 199
 200         private void on_search_finished (int movies) {
 201                 more_movies_available = (movies > 100); // FIXME
 202         }
 203
 204         private void title_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 205                 Movie movie;
 206                 string markup;
 207
 208                 model.get (iter, MovieListStore.Columns.MOVIE, out movie,
 209                                  MovieListStore.Columns.MARKUP, out markup);
 210                 title_renderer.markup = markup;
 211                 secondary_renderer.text = movie.secondary;
 212         }
 213
 214         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 215                 string rating;
 216                 Movie movie;
 217
 218                 model.get (iter, MovieListStore.Columns.RATING, out rating,
 219                                  MovieListStore.Columns.MOVIE, out movie);
 220                 rating_renderer.text = rating;
 221                 if (movie.julian_date != 0) {
 222                         var date = Date ();
 223                         date.set_julian (movie.julian_date);
 224                         var s = new char[64];
 225                         date.strftime (s, "%x");
 226                         date_renderer.text = (string) s;
 227                 } else {
 228                         date_renderer.text = "";
 229                 }
 230         }
 231 }