git.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         private bool more_movies_available;
  28         private CellRendererText title_renderer;
  29         private CellRendererText secondary_renderer;
  30         private CellRendererText rating_renderer;
  31         private CellRendererText date_renderer;
  32
  33         public signal void movie_activated (Movie movie);
  34
  35         public MovieListView (Gtk.Window window) {
  36                 store = new MovieListStore ();
  37
  38                 // Add filter wrapper
  39                 var filtered_store = new TreeModelFilter (store, null);
  40
  41                 // Add sort wrapper
  42                 sorted_store = new TreeModelSort.with_model (filtered_store);
  43
  44                 // Tree View
  45                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  46                 tree.set_headers_visible (false);
  47
  48                 add (tree);
  49
  50                 tree.set_rules_hint (true);
  51
  52                 // Tree selection object
  53                 var selection = tree.get_selection ();
  54                 selection.set_mode (SelectionMode.SINGLE);
  55
  56                 // Title column with poster
  57                 var title_column = new TreeViewColumn ();
  58                 title_column.set_title (_("Movie"));
  59                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  60                 title_column.set_reorderable (false);
  61                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  62                 title_column.set_expand (true);
  63
  64                 // Add poster icon to column
  65                 var pixbuf_renderer = new CellRendererPixbuf ();
  66                 pixbuf_renderer.width = 64;
  67                 pixbuf_renderer.xalign = 0.0f;
  68                 title_column.pack_start (pixbuf_renderer, false);
  69                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  70
  71                 // Add text to column
  72                 var vbox_renderer = new CellRendererVBox ();
  73
  74                 title_renderer = new CellRendererText ();
  75                 title_renderer.yalign = 1.0f;
  76                 title_renderer.ellipsize = Pango.EllipsizeMode.END;
  77
  78                 vbox_renderer.append (title_renderer, true);
  79
  80                 // Add secondary text to column (Genres, Director, etc.)
  81                 secondary_renderer = new CellRendererText ();
  82                 secondary_renderer.yalign = 0;
  83                 secondary_renderer.ellipsize = Pango.EllipsizeMode.END;
  84                 secondary_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryColor");
  85
  86                 vbox_renderer.append (secondary_renderer, true);
  87
  88                 title_column.pack_start (vbox_renderer, true);
  89                 title_column.set_cell_data_func (vbox_renderer, title_data_func);
  90
  91                 tree.append_column (title_column);
  92
  93                 // Sort by title
  94                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
  95
  96                 // Year column
  97                 var renderer = new CellRendererText ();
  98                 var year_column = new TreeViewColumn ();
  99                 year_column.set_title (_("Rating"));
 100                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 101                 year_column.set_reorderable (false);
 102                 year_column.set_sort_order (SortType.DESCENDING);
 103                 year_column.pack_start (renderer, true);
 104                 year_column.set_cell_data_func (renderer, year_data_func);
 105                 tree.append_column (year_column);
 106
 107                 // Rating column
 108                 var rating_column = new TreeViewColumn ();
 109                 rating_column.set_title (_("Rating"));
 110                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 111                 rating_column.set_reorderable (false);
 112                 rating_column.set_sort_order (SortType.DESCENDING);
 113                 rating_column.xalign = (float) 1.0;
 114
 115                 vbox_renderer = new CellRendererVBox ();
 116
 117                 rating_renderer = new CellRendererText ();
 118         //      rating_renderer.yalign = 1.0f;
 119
 120                 vbox_renderer.append (rating_renderer, true);
 121
 122                 date_renderer = new CellRendererText ();
 123                 date_renderer.yalign = 0;
 124                 date_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryColor");
 125
 126         //      vbox_renderer.append (date_renderer, true);
 127
 128                 rating_column.pack_start (vbox_renderer, true);
 129                 rating_column.set_cell_data_func (vbox_renderer, rating_data_func);
 130
 131                 tree.append_column (rating_column);
 132
 133                 // Connect signals
 134                 get_vadjustment ().value_changed.connect (on_adjustment_value_changed);
 135                 tree.row_activated.connect (on_row_activated);
 136                 store.search_finished.connect (on_search_finished);
 137         }
 138
 139         public void set_hildon_ui_mode (UIMode mode) {
 140                 var selection = tree.get_selection ();
 141
 142                 if (mode == UIMode.NORMAL) {
 143                         selection.set_mode (SelectionMode.NONE);
 144                 }
 145                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 146                 if (mode == UIMode.EDIT) {
 147                         selection.set_mode (SelectionMode.MULTIPLE);
 148                 }
 149         }
 150
 151         public unowned TreeSelection get_selection () {
 152                 return tree.get_selection ();
 153         }
 154
 155         private Pango.AttrList get_attributes (Gtk.Window window, string font_name, string color_name) {
 156                 Pango.AttrList attr_list = new Pango.AttrList ();
 157                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), font_name, null, typeof (void));
 158                 if (style != null) {
 159                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
 160                         attr_list.insert ((owned) attr_font_desc);
 161                 }
 162                 Gdk.Color color;
 163                 window.ensure_style ();
 164                 if (window.style.lookup_color (color_name, out color)) {
 165                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
 166                         attr_list.insert ((owned) attr_color);
 167                 }
 168                 return attr_list;
 169         }
 170
 171         // TODO: after scrolling down 80% of the list, load more
 172         //       results if available.
 173         private void on_adjustment_value_changed () {
 174                 if (more_movies_available) {
 175                         var vadj = get_vadjustment ();
 176                         if (vadj.value > 0.8 * vadj.upper) {
 177                                 Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 178                                 more_movies_available = false;
 179                         }
 180                 }
 181         }
 182
 183         private void on_row_activated (TreeView tree, TreePath path, TreeViewColumn column) {
 184                 TreeModel model = tree.model;
 185                 TreeIter iter;
 186
 187                 if (model.get_iter (out iter, path)) {
 188                         Movie movie;
 189                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 190                         movie_activated (movie);
 191                 }
 192         }
 193
 194         private void on_search_finished (int movies) {
 195                 more_movies_available = (movies > 100); // FIXME
 196         }
 197
 198         private void title_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 199                 Movie movie;
 200
 201                 model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 202                 title_renderer.text = movie.title;
 203                 secondary_renderer.text = movie.secondary;
 204         }
 205
 206         private void year_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 207                 int year;
 208
 209                 model.get (iter, MovieListStore.Columns.YEAR, out year);
 210                 ((CellRendererText) cell).text = (year > 0) ? year.to_string () : "";
 211         }
 212
 213         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 214                 int rating;
 215                 Movie movie;
 216
 217                 model.get (iter, MovieListStore.Columns.RATING, out rating,
 218                                  MovieListStore.Columns.MOVIE, out movie);
 219                 rating_renderer.text = (rating > 0) ? "%d.%d".printf (rating / 10, rating % 10) : "";
 220                 date_renderer.text = "%u".printf (movie.julian_date);
 221         }
 222 }