git.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         public signal void movie_activated (Movie movie);
  28
  29         construct {
  30                 store = new MovieListStore ();
  31
  32                 // Add filter wrapper
  33                 var filtered_store = new TreeModelFilter (store, null);
  34
  35                 // Add sort wrapper
  36                 sorted_store = new TreeModelSort.with_model (filtered_store);
  37
  38                 // Tree View
  39                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  40                 tree.set_headers_visible (false);
  41
  42                 add (tree);
  43
  44                 tree.set_rules_hint (true);
  45
  46                 // Tree selection object
  47                 var selection = tree.get_selection ();
  48                 selection.set_mode (SelectionMode.SINGLE);
  49
  50                 // Title column with poster
  51                 var title_column = new TreeViewColumn ();
  52                 title_column.set_title (_("Movie"));
  53                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  54                 title_column.set_reorderable (false);
  55                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  56                 title_column.set_expand (true);
  57
  58                 // Add poster icon to column
  59                 var pixbuf_renderer = new CellRendererPixbuf ();
  60                 pixbuf_renderer.width = 64;
  61                 title_column.pack_start (pixbuf_renderer, false);
  62                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  63
  64                 // Add text to column
  65                 var vbox_renderer = new CellRendererVBox ();
  66
  67                 var renderer = new CellRendererText ();
  68                 renderer.set ("ellipsize", Pango.EllipsizeMode.END);
  69                 title_column.add_attribute (renderer, "text", MovieListStore.Columns.TITLE);
  70
  71                 vbox_renderer.append (renderer, true);
  72                 vbox_renderer.set_data ("title", renderer);
  73
  74                 // Add secondary text to column (Genres, Director, etc.)
  75                 renderer = new CellRendererText ();
  76                 renderer.set ("ellipsize", Pango.EllipsizeMode.END);
  77
  78                 Pango.AttrList attr_list = new Pango.AttrList ();
  79                 var style = Gtk.rc_get_style_by_paths (this.get_settings (), "SmallSystemFont", null, typeof (void));
  80                 if (style != null) {
  81                         Pango.Attribute attr_font_desc = Pango.attr_font_desc_new (style.font_desc.copy ());
  82                         attr_list.insert ((owned) attr_font_desc);
  83                 } else {
  84                         Pango.Attribute attr_font_scale = Pango.attr_scale_new (Pango.Scale.SMALL);
  85                         attr_list.insert ((owned) attr_font_scale);
  86                 }
  87                 Gdk.Color color;
  88                 if (!style.lookup_color ("SecondaryTextColor", out color)) {
  89                         Gdk.Color.parse ("grey", out color);
  90                 }
  91                 Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
  92                 attr_list.insert ((owned) attr_color);
  93                 renderer.attributes = attr_list;
  94
  95                 vbox_renderer.append (renderer, true);
  96                 vbox_renderer.set_data ("secondary", renderer);
  97
  98                 title_column.pack_start (vbox_renderer, true);
  99                 title_column.set_cell_data_func (vbox_renderer, vbox_data_func);
 100
 101                 tree.append_column (title_column);
 102
 103                 // Sort by title
 104                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 105
 106                 // Year column
 107                 renderer = new CellRendererText ();
 108                 var year_column = new TreeViewColumn.with_attributes (_("Year"), renderer, "text", MovieListStore.Columns.YEAR);
 109                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 110                 year_column.set_reorderable (false);
 111                 year_column.set_sort_order (SortType.DESCENDING);
 112                 tree.append_column (year_column);
 113
 114                 // Rating column
 115                 renderer = new CellRendererText ();
 116                 var rating_column = new TreeViewColumn.with_attributes (_("Rating"), renderer, "text", MovieListStore.Columns.RATING);
 117                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 118                 rating_column.set_reorderable (false);
 119                 rating_column.set_sort_order (SortType.DESCENDING);
 120                 rating_column.set_cell_data_func (renderer, rating_data_func);
 121                 rating_column.xalign = (float) 1.0;
 122                 tree.append_column (rating_column);
 123
 124                 // Connect signals
 125                 tree.row_activated.connect (on_row_activated);
 126         }
 127
 128         private void on_row_activated (TreeView tree, TreePath path_, TreeViewColumn column) {
 129                 TreePath path = path_.copy (); // FIXME - calling model.get_iter with path_ directly causes a C qualifier warning
 130                 TreeModel model = tree.model;
 131                 TreeIter iter;
 132
 133                 if (model.get_iter (out iter, path)) {
 134                         Movie movie;
 135                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 136                         movie_activated (movie);
 137                 }
 138         }
 139
 140         private void vbox_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 141                 Movie movie;
 142                 CellRendererText renderer;
 143
 144                 model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 145
 146                 renderer = (CellRendererText) cell.get_data ("title");
 147                 renderer.text = movie.title;
 148
 149                 renderer = (CellRendererText) cell.get_data ("secondary");
 150                 renderer.text = movie.secondary;
 151         }
 152
 153         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 154                 int rating;
 155
 156                 model.get (iter, MovieListStore.Columns.RATING, out rating);
 157                 ((CellRendererText) cell).text = "%d.%d".printf (rating / 10, rating % 10);
 158         }
 159 }