git.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml sql network
   2
   3 INCLUDEPATH += $$PWD \
   4     $$PWD/model \
   5     $$PWD/widgets
   6
   7 SOURCES += \
   8     main.cpp \
   9     mainwindow.cpp \
  10     bookview.cpp \
  11     model/unzip/unzip.c \
  12     model/unzip/ioapi.c \
  13     model/extractzip.cpp \
  14     model/library.cpp \
  15     model/book.cpp \
  16     librarydialog.cpp \
  17     devtools.cpp \
  18     infodialog.cpp \
  19     widgets/translucentbutton.cpp \
  20     settingswindow.cpp \
  21     model/settings.cpp \
  22     bookmarksdialog.cpp \
  23     model/sortedlibrary.cpp \
  24     bookmarkinfodialog.cpp \
  25     widgets/dyalog.cpp \
  26     chaptersdialog.cpp \
  27     fullscreenwindow.cpp \
  28     trace.cpp \
  29     widgets/toolbuttonbox.cpp \
  30     model/bookfinder.cpp \
  31     widgets/listwindow.cpp \
  32     widgets/progress.cpp \
  33     adopterwindow.cpp \
  34     platform.cpp \
  35     model/bookdb.cpp \
  36     searchdialog.cpp \
  37     search.cpp \
  38     widgets/flickable.cpp \
  39     searchresultsdialog.cpp \
  40     searchresultinfodialog.cpp \
  41     widgets/progressdialog.cpp \
  42     widgets/splash.cpp \
  43     widgets/mainbase.cpp
  44
  45 HEADERS += \
  46     mainwindow.h \
  47     bookview.h \
  48     model/opshandler.h \
  49     model/unzip/unzip.h \
  50     model/unzip/ioapi.h \
  51     model/extractzip.h \
  52     model/library.h \
  53     model/book.h \
  54     librarydialog.h \
  55     devtools.h \
  56     infodialog.h \
  57     widgets/translucentbutton.h \
  58     settingswindow.h \
  59     model/settings.h \
  60     bookmarksdialog.h \
  61     model/xmlerrorhandler.h \
  62     model/containerhandler.h \
  63     model/sortedlibrary.h \
  64     model/ncxhandler.h \
  65     bookmarkinfodialog.h \
  66     widgets/dyalog.h \
  67     chaptersdialog.h \
  68     fullscreenwindow.h \
  69     trace.h \
  70     widgets/toolbuttonbox.h \
  71     model/bookfinder.h \
  72     widgets/listwindow.h \
  73     widgets/progress.h \
  74     adopterwindow.h \
  75     model/xmlhandler.h \
  76     platform.h \
  77     model/bookdb.h \
  78     searchdialog.h \
  79     search.h \
  80     widgets/flickable.h \
  81     searchresultsdialog.h \
  82     searchresultinfodialog.h \
  83     widgets/progressdialog.h \
  84     widgets/splash.h \
  85     widgets/mainbase.h
  86
  87 RESOURCES += \
  88     dorian.qrc
  89
  90 OTHER_FILES += \
  91     TODO.txt \
  92     pkg/acknowledgements.txt \
  93     pkg/maemo/postinst \
  94     pkg/maemo/dorian.desktop \
  95     pkg/maemo/control \
  96     pkg/maemo/changelog \
  97     pkg/maemo/build.sh \
  98     styles/night.css \
  99     pkg/changelog \
 100     pkg/maemo/build-scratchbox.sh \
 101     styles/sand.css \
 102     styles/default.css \
 103     pkg/version.txt \
 104     styles/sand.js \
 105     styles/night.js \
 106     styles/default.js \
 107     styles/day.js \
 108     www/index.html \
 109     pkg/maemo/autobuild.sh \
 110     pkg/maemo/autobuild-scratchbox.sh \
 111     LICENSE.txt \
 112     pkg/symbian/book.svg \
 113     pkg/symbian/clean.bat \
 114     pkg/maemo/icon-48/dorian.png \
 115     pkg/maemo/icon-scalable/dorian.png
 116
 117 DEFINES += \
 118     USE_FILE32API
 119
 120 !symbian {
 121     DEFINES += DORIAN_TEST_MODEL
 122     include(model/modeltest/modeltest.pri)
 123 }
 124
 125 unix {
 126     symbian {
 127     } else {
 128         LIBS += -lz
 129     }
 130 }
 131
 132 win32 {
 133     DEFINES += ZLIB_WINAPI
 134     INCLUDEPATH += $$PWD/model/zlib
 135     LIBS += pkg/win32/zlibstat.lib
 136 }
 137
 138 symbian {
 139     TARGET = Dorian
 140     TARGET.UID3 = 0xA89FC85B
 141     TARGET.CAPABILITY = UserEnvironment NetworkServices ReadUserData \
 142         WriteUserData
 143     TARGET.EPOCHEAPSIZE = 0x100000 0x4000000
 144     ICON = $$PWD/pkg/symbian/book.svg
 145
 146     # FIXME: Package header for Qt 4.6.2:
 147     packageheader = \
 148         "$${LITERAL_HASH}{\"Dorian\"},(0xA89FC85B),0,4,5" \
 149         "[0x101F7961],0,0,0,{\"S60ProductID\"}" \
 150         "[0x102032BE],0,0,0,{\"S60ProductID\"}" \
 151         "[0x102752AE],0,0,0,{\"S60ProductID\"}" \
 152         "[0x1028315F],0,0,0,{\"S60ProductID\"}"
 153     default_deployment.pkg_prerules = packageheader
 154
 155     # FIXME: Package header for Qt 4.6.3 or later:
 156     # packageheader = "$${LITERAL_HASH}{\"Dorian\"},(0xA89FC85B),0,4,5"
 157     # my_deployment.pkg_prerules = packageheader
 158     # DEPLOYMENT += my_deployment
 159
 160     INCLUDEPATH += $(QTDIR)/src/3rdparty/zlib
 161     HEADERS += \
 162         widgets/flickcharm.h \
 163         widgets/mediakeysobserver.h
 164     SOURCES += \
 165         widgets/flickcharm.cpp \
 166         widgets/mediakeysobserver.cpp
 167     LIBS += -lremconinterfacebase -lremconcoreapi -lcone -leikcore -lavkon
 168 }
 169
 170 maemo5 {
 171     QT += maemo5 dbus
 172     isEmpty(PREFIX) {
 173         PREFIX = /usr
 174     }
 175     BINDIR = $$PREFIX/bin
 176     DATADIR =$$PREFIX/share
 177     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 178
 179     # For "make install"
 180
 181     INSTALLS += target desktop icon48 iconscalable
 182
 183     target.path = $$BINDIR
 184
 185     desktop.path = $$DATADIR/applications/hildon
 186     desktop.files += pkg/maemo/dorian.desktop
 187
 188     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 189     icon48.files += pkg/maemo/icon-48/dorian.png
 190
 191     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 192     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 193 }