git.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml
   2
   3 SOURCES += \
   4     main.cpp \
   5     mainwindow.cpp \
   6     bookview.cpp \
   7     unzip/unzip.c \
   8     unzip/ioapi.c \
   9     extractzip.cpp \
  10     library.cpp \
  11     book.cpp \
  12     librarydialog.cpp \
  13     devtools.cpp \
  14     infodialog.cpp \
  15     translucentbutton.cpp \
  16     settingswindow.cpp \
  17     settings.cpp \
  18     bookmarksdialog.cpp \
  19     sortedlibrary.cpp \
  20     bookmarkinfodialog.cpp \
  21     dialog.cpp \
  22     chaptersdialog.cpp \
  23     fullscreenwindow.cpp
  24
  25 HEADERS += \
  26     mainwindow.h \
  27     bookview.h \
  28     selectionsuppressor.h \
  29     opshandler.h \
  30     unzip/unzip.h \
  31     unzip/ioapi.h \
  32     extractzip.h \
  33     library.h \
  34     book.h \
  35     librarydialog.h \
  36     devtools.h \
  37     infodialog.h \
  38     translucentbutton.h \
  39     settingswindow.h \
  40     settings.h \
  41     bookmarksdialog.h \
  42     xmlerrorhandler.h \
  43     containerhandler.h \
  44     sortedlibrary.h \
  45     ncxhandler.h \
  46     bookmarkinfodialog.h \
  47     dialog.h \
  48     chaptersdialog.h \
  49     fullscreenwindow.h
  50
  51 RESOURCES += \
  52     dorian.qrc
  53
  54 OTHER_FILES += \
  55     TODO.txt \
  56     pkg/acknowledgements.txt \
  57     pkg/maemo/postinst \
  58     pkg/maemo/dorian.desktop \
  59     pkg/maemo/control \
  60     pkg/maemo/changelog \
  61     pkg/maemo/build.sh \
  62     styles/night.css \
  63     pkg/changelog \
  64     pkg/maemo/build-scratchbox.sh \
  65     styles/sand.css \
  66     styles/default.css \
  67     pkg/version.txt \
  68     styles/sand.js \
  69     styles/night.js \
  70     styles/default.js \
  71     styles/day.js \
  72     www/index.html
  73
  74 DEFINES += \
  75     USE_FILE32API \
  76     DORIAN_TEST_MODEL
  77
  78 include(modeltest/modeltest.pri)
  79
  80 unix {
  81     LIBS += -lz
  82 }
  83 windows {
  84     # FIXME: Build zlib, too
  85 }
  86 maemo5 {
  87     QT += maemo5
  88     isEmpty(PREFIX) {
  89         PREFIX = /usr
  90     }
  91     BINDIR = $$PREFIX/bin
  92     DATADIR =$$PREFIX/share
  93     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  94
  95     # For "make install"
  96
  97     INSTALLS += target desktop icon48 iconscalable
  98
  99     target.path = $$BINDIR
 100
 101     desktop.path = $$DATADIR/applications/hildon
 102     desktop.files += pkg/maemo/dorian.desktop
 103
 104     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 105     icon48.files += pkg/maemo/icon-48/dorian.png
 106
 107     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 108     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 109 }