git.maemo.org Git - mardrone/blob - mardrone/imports/Qt/labs/components/native/Switch.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the Qt Components project.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.1
  42
  43 /*
  44 Class: Switch
  45    The Switch component is similar to the CheckBox component but instead of
  46    selecting items it should be used when setting options to On/Off.
  47 */
  48 Item {
  49     id: root
  50
  51     width: slider.width
  52     height: slider.height
  53
  54     /*
  55     * Property: checked
  56      * [bool=false] The checked state of switch
  57      */
  58     property bool checked: false
  59
  60     // Styling for the Switch
  61     property Style platformStyle: SwitchStyle {}
  62
  63     //Deprecated, TODO Remove this on w13
  64     property alias style: root.platformStyle
  65
  66     property alias platformMouseAnchors: mouseArea.anchors
  67
  68     /*
  69     * Property: enabled
  70      * [bool=true] Enables/Disables the component. Notice that the disable state is not Toolkit compliant
  71      * and not present inside the qt-components
  72      */
  73
  74     Item {
  75         id: slider
  76
  77         width: 66
  78         height: 42
  79
  80         state: root.checked ? "checked" : "unchecked"
  81
  82         property real knobPos: (knob.x - platformStyle.minKnobX) / (platformStyle.maxKnobX - platformStyle.minKnobX)
  83
  84         Image {
  85             source: platformStyle.switchOn
  86             opacity: slider.knobPos
  87         }
  88         Image {
  89             source: platformStyle.switchOff
  90             opacity: 1.0 - slider.knobPos
  91         }
  92
  93         states: [
  94             State {
  95                 name: "unchecked"
  96                 PropertyChanges { target: knob; x: platformStyle.minKnobX }
  97             },
  98             State {
  99                 name: "checked"
 100                 PropertyChanges { target: knob; x: platformStyle.maxKnobX }
 101             }
 102         ]
 103
 104         transitions: [
 105             Transition {
 106                 SmoothedAnimation { properties: "x"; velocity: 500; maximumEasingTime: 0 }
 107             }
 108         ]
 109
 110         // thumb (shadow)
 111         Image {
 112             id: knob
 113
 114             // thumb (inline)
 115             Image {
 116                 width: 30
 117                 height: 30
 118                 x: 0
 119                 y: -2
 120                 source: (slider.enabled ? (mouseArea.pressed ? platformStyle.thumbPressed : platformStyle.thumb) : platformStyle.thumbDisabled)
 121             }
 122
 123             source: platformStyle.shadow
 124
 125             y: 8
 126
 127             width: 30
 128             height: 30
 129         }
 130
 131         MouseArea {
 132             id: mouseArea
 133             property int downMouseX
 134             property int downKnobX
 135             anchors {
 136                 fill: parent
 137                 rightMargin: platformStyle.mouseMarginRight
 138                 leftMargin: platformStyle.mouseMarginLeft
 139                 topMargin: platformStyle.mouseMarginTop
 140                 bottomMargin: platformStyle.mouseMarginBottom
 141             }
 142
 143             function snap() {
 144                 if (knob.x < (platformStyle.maxKnobX + platformStyle.minKnobX) / 2) {
 145                     if (root.checked) {
 146                         root.checked = false;
 147                     } else {
 148                         knob.x = platformStyle.minKnobX;
 149                     }
 150                 } else {
 151                     if (!root.checked) {
 152                         root.checked = true;
 153                     } else {
 154                         knob.x = platformStyle.maxKnobX;
 155                     }
 156                 }
 157             }
 158
 159             onPressed: {
 160                 downMouseX = mouseX;
 161                 downKnobX = knob.x;
 162             }
 163
 164             onPositionChanged: {
 165                 var newKnobX = downKnobX - (downMouseX - mouseX);
 166                 knob.x = newKnobX < platformStyle.minKnobX ? platformStyle.minKnobX : newKnobX > platformStyle.maxKnobX ? platformStyle.maxKnobX : newKnobX;
 167             }
 168
 169             onReleased: {
 170                 if (Math.abs(downMouseX - mouseX) < 5)
 171                     root.checked = !root.checked;
 172                 else
 173                     snap();
 174             }
 175
 176             onCanceled: {
 177                 snap();
 178             }
 179
 180         }
 181     }
 182 }