git.maemo.org Git - mardrone/blob - mardrone/imports/com/nokia/android.1.1/Popup.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the Qt Components project.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.1
  42 import "." 1.1
  43 import "AppManager.js" as Utils
  44
  45 Item {
  46     id: root
  47
  48     property Item visualParent
  49     property int status: DialogStatus.Closed
  50     property int animationDuration: 500
  51     property Item fader
  52     property bool platformInverted: false
  53
  54     signal faderClicked
  55
  56     function open() {
  57         if (status == DialogStatus.Open || status == DialogStatus.Opening)
  58             return
  59
  60         var notify = false
  61         if (!fader) {
  62             fader = faderComponent.createObject(visualParent ? visualParent : Utils.rootObject())
  63             notify = true
  64         }
  65
  66         fader.animationDuration = root.animationDuration
  67         root.parent = fader
  68         status = DialogStatus.Opening
  69         fader.state = "Visible"
  70
  71         if (notify)
  72             platformPopupManager.privateNotifyPopupOpen()
  73     }
  74
  75     function close() {
  76         if (status != DialogStatus.Closed) {
  77             status = DialogStatus.Closing
  78             if (fader)
  79                 fader.state = "Hidden"
  80         }
  81     }
  82
  83     onStatusChanged: {
  84         if (status == DialogStatus.Closed && fader) {
  85             // Temporarily setting root window as parent
  86             // otherwise transition animation jams
  87             root.parent = null
  88             fader.destroy()
  89             fader = null // Prevent reuse in open()
  90             root.parent = parentCache.oldParent
  91             platformPopupManager.privateNotifyPopupClose()
  92         }
  93     }
  94
  95     Component.onCompleted: {
  96         parentCache.oldParent = parent
  97     }
  98
  99     //if this is not given, application may crash in some cases
 100     Component.onDestruction: {
 101         if (parentCache.oldParent != null) {
 102             parent = parentCache.oldParent
 103         }
 104     }
 105
 106     QtObject {
 107         id: parentCache
 108         property QtObject oldParent: null
 109     }
 110
 111     //This eats mouse events when popup area is clicked
 112     MouseArea {
 113         anchors.fill: parent
 114     }
 115
 116     Component {
 117         id: faderComponent
 118
 119         Fader {
 120             platformInverted: root.platformInverted
 121             onClicked: root.faderClicked()
 122         }
 123     }
 124 }