git.maemo.org Git - marketstoday/blob - src/src.pro

   1 TEMPLATE = app
   2
   3 CONFIG += debug
   4
   5 exists($$QMAKE_INCDIR_QT"/../qmsystem2/qmkeys.h"){
   6    DEFINES += Q_WS_MAEMO_6
   7 }
   8
   9 QT += script \
  10     declarative \
  11     sql \
  12     network
  13
  14 TARGET = marketstoday
  15 HEADERS += \
  16     cpp/marketstodayqmlview.h \
  17     cpp/configqmlview.h \
  18     cpp/logutility.h \
  19     cpp/connectionutility.h \
  20     cpp/sharedcontext.h
  21
  22 SOURCES += cpp/main.cpp \
  23     cpp/marketstodayqmlview.cpp \
  24     cpp/configqmlview.cpp
  25 VPATH += cpp
  26
  27 MOC_DIR = cpp/.mocs
  28 OBJECTS_DIR = cpp/.objs
  29
  30 OTHER_FILES += \
  31     qml/Config.qml \
  32     qml/ConfigOptionsComponent.qml \
  33     qml/ConfigParametersComponent.qml \
  34     qml/ConfigTickersComponent.qml \
  35     qml/Library/TitleBar.qml \
  36     qml/Library/ToolBar.qml \
  37     qml/Library/js/DBUtility.js \
  38     qml/Library/js/ISODate.js \
  39     qml/Library/js/Common.js \
  40     qml/Library/js/XMLParser.js \
  41     qml/Library/js/CoreLogic.js \
  42     qml/MarketsTodayWidget.qml \
  43     qml/MarketsTodayApp.qml \
  44     qml/Library/MenuBar.qml \
  45     qml/Library/Button.qml \
  46     qml/StockDetailsComponent.qml \
  47     qml/StockDetailsRow.qml \
  48     qml/Library/Loading.qml \
  49     qml/MarketsTodayLegacyApp.qml \
  50     qml/Library/CustomGestureArea.qml \
  51     qml/StockDetailsComponentLegacy.qml
  52
  53 RESOURCES += \
  54     resources.qrc
  55
  56 symbian {
  57
  58     TARGET.UID3 = 0xE6159209
  59     # Allow network access on Symbian
  60     TARGET.CAPABILITY += NetworkServices ReadUserData
  61 }
  62 else:unix {
  63    INSTALLDIR = /../debian/marketstoday
  64    INSTALLS += target app icon26 icon32 icon48 icon64 appicon
  65
  66    # Maemo 5 specific paths (The exists function is used to make sure the widget is deployed to FREMANTLE_X86 target in Scratchbox
  67    # Scratchbox is not identified as maemo or maemo5 platform
  68    maemo5 | exists(/usr/bin/hildon-home) {
  69     message("Deploying widget")
  70
  71     INSTALLS += widget
  72     widget.path = /usr/share/applications/hildon-home
  73     widget.files += data/marketstoday-widget.desktop
  74     app.path = /usr/share/applications/hildon
  75     app.files += data/marketstoday-app.desktop
  76    }
  77    else{
  78     app.path = /usr/share/applications
  79     app.files += data/marketstoday-app-meego.desktop
  80    }
  81
  82    target.path = $$INTSALLDIR/opt/marketstoday/
  83
  84    icon26.path = /usr/share/icons/hicolor/26x26/apps
  85    icon26.files += data/icons/26x26/marketstoday.png
  86
  87    icon32.path = /usr/share/icons/hicolor/32x32/apps
  88    icon32.files += data/icons/32x32/marketstoday.png
  89
  90    icon48.path = /usr/share/icons/hicolor/48x48/apps
  91    icon48.files += data/icons/48x48/marketstoday.png
  92
  93    icon64.path = /usr/share/icons/hicolor/64x64/apps
  94    icon64.files += data/icons/64x64/marketstoday.png
  95
  96    appicon.path = /usr/share/icons/hicolor/80x80/apps
  97    appicon.files += data/icons/marketstoday_icon.png
  98 }
  99
 100 # Include Qt Maemo 5 Home screen widget adaptor
 101 include(qmaemo5homescreenadaptor/qmaemo5homescreenadaptor.pri)
 102
 103
 104
 105
 106
 107
 108
 109