git.maemo.org Git - mdictionary/blob - src/mdictionary/mdictionary.pro

   1 TARGET = mdictionary
   2 TEMPLATE = app
   3
   4 include(../../mdictionary.pri)
   5
   6 QT = core \
   7     gui \
   8     xml \
   9     xmlpatterns \
  10     sql \
  11     dbus \
  12     webkit
  13
  14 maemo5:QT += maemo5
  15
  16 SOURCES += gui/main.cpp \
  17     backbone/ConfigGenerator.cpp \
  18     gui/MainWindow.cpp \
  19     gui/SearchBarWidget.cpp \
  20     gui/WordListWidget.cpp \
  21     gui/TranslationWidget.cpp \
  22     backbone/backbone.cpp \
  23     gui/MenuWidget.cpp \
  24     gui/MenuTabWidget.cpp \
  25     gui/DictManagerWidget.cpp \
  26     gui/DictTypeSelectDialog.cpp \
  27     backbone/History.cpp \
  28     gui/HistoryListDialog.cpp \
  29     gui/WordListProxyStyle.cpp \
  30     backbone/Bookmarks.cpp \
  31     gui/SettingsWidget.cpp \
  32     gui/BookmarksWidget.cpp \
  33     gui/WelcomeScreenWidget.cpp \
  34     gui/AboutWidget.cpp \
  35     gui/TranslationTextEdit.cpp \
  36     gui/DBusAdapter.cpp \
  37     gui/NotifyManager.cpp
  38
  39 HEADERS += gui/MainWindow.h \
  40     backbone/ConfigGenerator.h \
  41     gui/AboutWidget.h \
  42     gui/SearchBarWidget.h \
  43     gui/WordListWidget.h \
  44     gui/TranslationWidget.h \
  45     backbone/backbone.h \
  46     ../include/translation.h \
  47     ../include/settings.h \
  48     ../include/CommonDictInterface.h \
  49     gui/MenuWidget.h \
  50     gui/MenuTabWidget.h \
  51     gui/DictManagerWidget.h \
  52     gui/DictTypeSelectDialog.h \
  53     ../include/History.h \
  54     gui/HistoryListDialog.h \
  55     ../include/GUIInterface.h \
  56     gui/WordListProxyStyle.h \
  57     backbone/Bookmarks.h \
  58     backbone/BookmarkTranslations.h \
  59     gui/SettingsWidget.h \
  60     gui/BookmarksWidget.h \
  61     gui/WelcomeScreenWidget.h \
  62     ../include/Notify.h \
  63     gui/TranslationTextEdit.h \
  64     ../include/AccentsNormalizer.h \
  65     ../include/DictDialog.h \
  66     gui/DBusAdapter.h \
  67     gui/NotifyManager.h
  68
  69 RESOURCES += ../../data/gui.qrc
  70
  71 TRANSLATIONS += pl_PL.ts \
  72                 en_US.ts
  73
  74 target.path = $$BIN_DIR
  75 INSTALLS += target
  76
  77 unix {
  78         maemo5 {
  79                 desktop.path = $$SHARE_DIR/applications/hildon
  80                 icon64.path = $$SHARE_DIR/icons/hicolor/64x64/hildon
  81         }
  82         !maemo5 {
  83                 desktop.path = $$SHARE_DIR/applications
  84                 icon64.path = $$SHARE_DIR/icons
  85         }
  86
  87         desktop.files += ../../data/other/$${TARGET}.desktop
  88         icon64.files += ../../data/icons/64x64/$${TARGET}.png
  89
  90         bookmarks.path = $$DATA_DIR
  91         bookmarks.files += ../../data/icons/16x16/staron.png
  92
  93         service.path = $$SHARE_DIR/dbus-1/services
  94         service.files += ../../data/other/com.comarch.mdictionary.service
  95
  96         INSTALLS += desktop icon64 bookmarks service
  97 }
  98
  99
 100 check.commands = echo 'No check here'
 101 QMAKE_EXTRA_TARGETS += check