git.maemo.org Git - mdictionary/blob - src/plugins/xdxf/xdxf.pro

   1 TARGET = xdxf
   2
   3 include(../plugin.pri)
   4
   5 QT = core \
   6     gui \
   7     xml \
   8     sql \
   9     network\
  10     declarative
  11
  12 maemo5 {
  13     LIBS += -lbz2 \
  14 }
  15
  16 !maemo5 {
  17     LIBS += -ltar \
  18         -lbz2
  19 }
  20 maemo5:QT += maemo5
  21
  22 SOURCES += xdxfplugin.cpp \
  23     TranslationXdxf.cpp \
  24     XdxfDictDialog.cpp \
  25     XdxfCachingDialog.cpp \
  26     XdxfDialog.cpp \
  27     XdxfDictDownloader.cpp \
  28     XdxfDictSelectDialog.cpp \
  29     XdxfDictDownloadProgressDialog.cpp \
  30     DictsModel.cpp \
  31     HttpDownloader.cpp \
  32     DictsListModel.cpp \
  33     ../../include/ComboBoxModel.cpp
  34
  35 HEADERS += xdxfplugin.h \
  36     TranslationXdxf.h \
  37     ../../include/DictDialog.h \
  38     XdxfDictDialog.h \
  39     ../../include/translation.h \
  40     ../../include/settings.h \
  41     ../../include/CommonDictInterface.h \
  42     ../../include/ComboBoxModel.h \
  43     XdxfCachingDialog.h \
  44     XdxfDialog.h \
  45     XdxfDictDownloader.h \
  46     XdxfDictSelectDialog.h \
  47     XdxfDictDownloadProgressDialog.h \
  48     DownloadDict.h \
  49     DictsModel.h \
  50     DictsProxyModel.h \
  51     HttpDownloader.h \
  52     DictsListModel.h \
  53     DictsProxyListModel.h
  54
  55 RESOURCES += xdxf.qrc
  56
  57 TRANSLATIONS += pl_PL.ts \
  58                 en_US.ts
  59
  60 OTHER_FILES += ../../mdictionary/qml/XdxfDialog.qml \
  61     ../../mdictionary/qml/XdxfDictDownloader.qml \
  62     ../../mdictionary/qml/TableWidget.qml \
  63     ../../mdictionary/qml/ScrollBar2.qml
  64
  65 unix {
  66     dicts.path = $$PLUGINS_DIR
  67     dicts.files += ../../../data/dicts/eng-us.xdxf
  68     dicts.files += ../../../data/dicts/eng-thai.xdxf
  69     plugin-icon.path = $$DATA_DIR
  70     plugin-icon.files += xdxf.png
  71
  72     meego {
  73         qmls.path = $$DATA_DIR/qml
  74         qmls.files += ../../mdictionary/qml/XdxfDialog.qml
  75     }
  76     else:maemo5 {
  77         qmls.path = $$DATA_DIR/qml
  78         qmls.files += ../../mdictionary/qml/XdxfDialog.qml
  79     }
  80     else {
  81         qmls.path = $$DATA_DIR/qml
  82         qmls.files += ../../mdictionary/qml/XdxfDialog.qml
  83         qmls.files += ../../mdictionary/qml/XdxfDictDownloader.qml
  84         qmls.files += ../../mdictionary/qml/TableWidget.qml
  85         qmls.files += ../../mdictionary/qml/ScrollBar2.qml
  86
  87     }
  88
  89     INSTALLS += dicts \
  90         plugin-icon\
  91         qmls
  92 }
  93 check.commands = echo \
  94                 'No check here'
  95 QMAKE_EXTRA_TARGETS += check