git.maemo.org Git - ptas/blob - zouba/qt4-maemo5/mkspecs/features/symbian/qt.prf

   1 contains(DEFINES, QT_MAKEDLL)|contains(DEFINES, QT_DLL) {
   2     CONFIG *= epocallowdlldata
   3 }
   4
   5 CONFIG += qtmain
   6
   7 load(qt)
   8
   9 # Allow .pro files to specify include path(s) to be prepended to the list.
  10 #
  11 # This allows the project to override the default ordering, whereby paths
  12 # relative to $$QMAKE_INCDIR_QT always come first.  This ordering can cause
  13 # problems when both the epoc32/include tree and a Qt include directory
  14 # contain a header of the same name - in this case, the Qt header is always
  15 # included by virtue of its path appearing first in the SYSTEMINCLUDE
  16 # directives in the generated MMP file.
  17 #
  18 # To work around this situation, the following line can be added to the .pro
  19 # file:
  20 #       PREPEND_INCLUDEPATH = /epoc32/include
  21 #
  22 INCLUDEPATH = $$PREPEND_INCLUDEPATH $$INCLUDEPATH
  23
  24 # Add dependency to Qt package to all other projects besides Qt libs.
  25 # Note: Qt libs with full capabilities has UID3 of 0x2001E61C,
  26 #       while self-signed version typically has temporary UID3 of 0xE001E61C.
  27 contains(CONFIG, qt):!contains(TARGET.UID3, 0x2001E61C):!contains(TARGET.UID3, 0xE001E61C) {
  28     default_deployment.pkg_prerules += \
  29         "; Default dependency to Qt libraries" \
  30         "(0x2001E61C), $${QT_MAJOR_VERSION}, $${QT_MINOR_VERSION}, $${QT_PATCH_VERSION},  {\"Qt\"}"
  31
  32     # Projects linking to webkit need dependency to webkit
  33     contains(QT, webkit): {
  34         default_deployment.pkg_prerules += \
  35             "; Dependency to Qt Webkit" \
  36             "(0x200267C2), $${QT_MAJOR_VERSION}, $${QT_MINOR_VERSION}, $${QT_PATCH_VERSION},  {\"QtWebKit\"}"
  37     }
  38 }
  39
  40 isEmpty(TARGET.EPOCSTACKSIZE):TARGET.EPOCSTACKSIZE = 0x14000
  41 isEmpty(TARGET.EPOCHEAPSIZE):TARGET.EPOCHEAPSIZE = 0x020000 0x800000