git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 QT += webkit network maemo5
   8 CONFIG += qt webkit mobility
   9 MOBILITY = location
  10
  11 TARGET = quandoparte
  12 TEMPLATE = app
  13 VERSION = 0.4.2
  14 VERSION_STRING = '\\"$${VERSION}\\"'
  15 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  16
  17 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  18
  19 SOURCES += main.cpp \
  20     settingsdialog.cpp \
  21     stationview.cpp \
  22     app.cpp \
  23     stationlistview.cpp \
  24     keypressforwarder.cpp \
  25     stationlistmodel.cpp \
  26     stationlistproxymodel.cpp
  27
  28 HEADERS += \
  29     settingsdialog.h \
  30     stationview.h \
  31     app.h \
  32     stationlistview.h \
  33     keypressforwarder.h \
  34     stationlistmodel.h \
  35     stationlistproxymodel.h
  36
  37 FORMS += \
  38     settingsdialog.ui \
  39     stationlistview.ui
  40
  41 symbian {
  42     TARGET.UID3 = 0xe30fb688
  43     # TARGET.CAPABILITY +=
  44     TARGET.EPOCSTACKSIZE = 0x14000
  45     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  46 }
  47
  48 OTHER_FILES += \
  49     quandoparte.desktop \
  50     icons/quandoparte.png \
  51     resources/quandoparte.css \
  52     resources/arrivals.css \
  53     resources/departures.css \
  54     $$replace(TRANSLATIONS, .ts, .qm) \
  55     resources/stations/stations.qpl \
  56     resources/stations/generatelist.xq \
  57     resources/stations/generateunclassifiedlist.xq
  58
  59 unix {
  60     isEmpty(PREFIX) {
  61         maemo5 {
  62             PREFIX=/opt/usr
  63         } else {
  64             PREFIX=/usr/local
  65         }
  66     }
  67     BINDIR=$$PREFIX/bin
  68     DESKTOPDIR=$$PREFIX/share/applications
  69     DATADIR=$$PREFIX/share/apps/$${TARGET}
  70     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  71 }
  72
  73 message(Installing to prefix $$PREFIX)
  74
  75 unix:!symbian {
  76     target.path = $$BINDIR
  77     INSTALLS += target
  78 }
  79
  80 unix:!symbian {
  81     desktopfile.files = $${TARGET}.desktop
  82     maemo5 {
  83         desktopfile.path = /usr/share/applications/hildon
  84     } else {
  85         desktopfile.path = $$DESKTOPDIR
  86     }
  87     INSTALLS += desktopfile
  88 }
  89
  90 unix:!symbian {
  91     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
  92     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
  93     stations.files = resources/stations/stations.qpl
  94
  95     i18n.path = $$DATADIR/i18n
  96     css.path = $$DATADIR/css
  97     stations.path = $$DATADIR/stations
  98
  99     icon48.files = icons/48x48/$${TARGET}.png
 100     icon64.files = icons/64x64/$${TARGET}.png
 101
 102     icon48.path = /usr/share/icons/hicolor/48x48/apps
 103     icon64.path = /usr/share/icons/hicolor/64x64/apps
 104
 105     INSTALLS += icon48
 106     INSTALLS += icon64
 107     INSTALLS += css
 108     INSTALLS += i18n
 109     INSTALLS += stations
 110 }
 111
 112 unix {
 113     desktopfile.files = $${TARGET}.desktop
 114     maemo5 {
 115         desktopfile.path = /usr/share/applications/hildon
 116     } else {
 117         desktopfile.path = $$DATADIR/applications
 118     }
 119     INSTALLS += desktopfile
 120 }