git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 QT += webkit network maemo5
   8
   9 TARGET = quandoparte
  10 TEMPLATE = app
  11 VERSION = 0.1.90
  12
  13 VERSION_STRING = '\\"$${VERSION}\\"'
  14 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  15
  16 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  17
  18 SOURCES += main.cpp \
  19     settingsdialog.cpp \
  20     stationview.cpp \
  21     app.cpp \
  22     stationlistview.cpp \
  23     keypressforwarder.cpp \
  24     stationlistmodel.cpp \
  25     stationlistproxymodel.cpp
  26
  27 HEADERS += \
  28     settingsdialog.h \
  29     stationview.h \
  30     app.h \
  31     stationlistview.h \
  32     keypressforwarder.h \
  33     stationlistmodel.h \
  34     stationlistproxymodel.h
  35
  36 FORMS += \
  37     settingsdialog.ui \
  38     stationlistview.ui
  39
  40 CONFIG += webkit mobility
  41 MOBILITY = location
  42
  43 symbian {
  44     TARGET.UID3 = 0xe30fb688
  45     # TARGET.CAPABILITY +=
  46     TARGET.EPOCSTACKSIZE = 0x14000
  47     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  48 }
  49
  50 OTHER_FILES += \
  51     debian/changelog \
  52     debian/compat \
  53     debian/control \
  54     debian/copyright \
  55     debian/README \
  56     debian/rules \
  57     quandoparte.desktop \
  58     icons/quandoparte.png \
  59     resources/quandoparte.css \
  60     resources/arrivals.css \
  61     resources/departures.css \
  62     $$replace(TRANSLATIONS, .ts, .qm) \
  63     resources/stations/stations.qpl
  64
  65 message($${OTHER_FILES})
  66
  67 unix:!symbian {
  68     maemo5 {
  69         target.path = /opt/usr/bin
  70     } else {
  71         target.path = /usr/local/bin
  72     }
  73     INSTALLS += target
  74 }
  75
  76 unix:!symbian {
  77     desktopfile.files = $${TARGET}.desktop
  78     maemo5 {
  79         desktopfile.path = /usr/share/applications/hildon
  80     } else {
  81         desktopfile.path = /usr/share/applications
  82     }
  83     INSTALLS += desktopfile
  84 }
  85
  86 unix:!symbian {
  87     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
  88     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
  89     stations.files = resources/stations/stations.qpl
  90     maemo5 {
  91         i18n.path = /opt/usr/share/apps/$${TARGET}/i18n
  92         css.path = /opt/usr/share/apps/$${TARGET}/css
  93         stations.path = /opt/usr/share/apps/$${TARGET}/stations
  94     } else {
  95         i18n.path = /usr/share/apps/$${TARGET}/i18n
  96         css.path = /usr/share/apps/$${TARGET}/css
  97         stations.path = /usr/share/apps/$${TARGET}/stations
  98     }
  99     icon48.files = icons/48x48/$${TARGET}.png
 100     icon64.files = icons/64x64/$${TARGET}.png
 101     icon48.path = /usr/share/icons/hicolor/48x48/apps
 102     icon64.path = /usr/share/icons/hicolor/64x64/apps
 103     INSTALLS += icon48
 104     INSTALLS += icon64
 105     INSTALLS += css
 106     INSTALLS += i18n
 107     INSTALLS += stations
 108 }
 109
 110 maemo5 {
 111     desktopfile.files = $${TARGET}.desktop
 112     desktopfile.path = /usr/share/applications/hildon
 113     INSTALLS += desktopfile
 114 }