git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 QT += webkit network
   8
   9 maemo5 {
  10     QT += maemo5
  11 }
  12
  13 harmattan {
  14     message(Compiling for the Harmattan platform)
  15 }
  16 maemo5 {
  17     message(Compiling for the Fremantle platform)
  18 }
  19 symbian {
  20     message(Compiling for the Symbian platform)
  21 }
  22 !harmattan:!maemo5:!symbian {
  23     message(Compiling for the Desktop platform)
  24 }
  25
  26 CONFIG += qt webkit mobility
  27 MOBILITY = location
  28
  29 TARGET = quandoparte
  30 TEMPLATE = app
  31 VERSION = 0.4.1
  32 VERSION_STRING = '\\"$${VERSION}\\"'
  33 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  34
  35 !debug {
  36     DEFINES += QT_NO_DEBUG_OUTPUT
  37 }
  38
  39 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  40
  41 SOURCES += main.cpp \
  42     settingsdialog.cpp \
  43     stationview.cpp \
  44     app.cpp \
  45     stationlistview.cpp \
  46     keypressforwarder.cpp \
  47     stationlistmodel.cpp \
  48     stationlistproxymodel.cpp
  49
  50 HEADERS += \
  51     settingsdialog.h \
  52     stationview.h \
  53     app.h \
  54     stationlistview.h \
  55     keypressforwarder.h \
  56     stationlistmodel.h \
  57     stationlistproxymodel.h
  58
  59 FORMS += \
  60     settingsdialog.ui \
  61     stationlistview.ui
  62
  63 symbian {
  64     TARGET.UID3 = 0xe30fb688
  65     # TARGET.CAPABILITY +=
  66     TARGET.EPOCSTACKSIZE = 0x14000
  67     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  68 }
  69
  70 OTHER_FILES += \
  71     quandoparte.desktop \
  72     icons/48x48/quandoparte.png \
  73     icons/64x64/quandoparte.png \
  74     icons/scalable/quandoparte.svg \
  75     icons/quandoparte.png \
  76     resources/quandoparte.css \
  77     resources/arrivals.css \
  78     resources/departures.css \
  79     $$replace(TRANSLATIONS, .ts, .qm) \
  80     resources/stations/stations.qpl \
  81     resources/stations/generatelist.xq \
  82     resources/stations/generateunclassifiedlist.xq
  83
  84 unix {
  85     isEmpty(PREFIX) {
  86         maemo5 {
  87             PREFIX=/opt/usr
  88             DESKTOPDIR=/usr/share/applications/hildon
  89         } else {
  90             PREFIX=/usr/local
  91             DESKTOPDIR=$$PREFIX/share/applications
  92         }
  93     }
  94     BINDIR=$$PREFIX/bin
  95     DATADIR=$$PREFIX/share/apps/$${TARGET}
  96     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  97 }
  98
  99 message(Installing to prefix $$PREFIX)
 100
 101 unix:!symbian {
 102     target.path = $$BINDIR
 103     INSTALLS += target
 104 }
 105
 106 unix:!symbian {
 107     desktopfile.files = $${TARGET}.desktop
 108     desktopfile.path = $$DESKTOPDIR
 109     INSTALLS += desktopfile
 110 }
 111
 112 unix:!symbian {
 113     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 114     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 115     stations.files = resources/stations/stations.qpl
 116
 117     i18n.path = $$DATADIR/i18n
 118     css.path = $$DATADIR/css
 119     stations.path = $$DATADIR/stations
 120
 121     icon48.files = icons/48x48/$${TARGET}.png
 122     icon64.files = icons/64x64/$${TARGET}.png
 123     iconscalable.files = icons/scalable/$${TARGET}.svg
 124
 125     icon48.path = /usr/share/icons/hicolor/48x48/apps
 126     icon64.path = /usr/share/icons/hicolor/64x64/apps
 127     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 128
 129     INSTALLS += icon48
 130     INSTALLS += icon64
 131     INSTALLS += iconscalable
 132     INSTALLS += css
 133     INSTALLS += i18n
 134     INSTALLS += stations
 135 }
 136
 137 unix {
 138     desktopfile.files = $${TARGET}.desktop
 139     maemo5 {
 140         desktopfile.path = /usr/share/applications/hildon
 141     } else {
 142         desktopfile.path = $$DATADIR/applications
 143     }
 144     INSTALLS += desktopfile
 145 }