git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 VERSION = 0.4.80
   8
   9 QT += webkit network
  10
  11 harmattan {
  12     QT += declarative
  13     PLATFORM = harmattan
  14     DEFINES += TARGET_PLATFORM_HARMATTAN
  15     # enable booster
  16     CONFIG += qdeclarative-boostable
  17     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden
  18     QMAKE_LFLAGS += -pie -rdynamic
  19     PLATFORM_SOURCES = view.cpp
  20     PLATFORM_HEADERS = view.h
  21 }
  22 maemo5 {
  23     QT += maemo5
  24     PLATFORM = fremantle
  25     DEFINES += TARGET_PLATFORM_FREMANTLE
  26     PLATFORM_SOURCES = \
  27         app.cpp \
  28         stationlistview.cpp \
  29         stationview.cpp \
  30         settingsdialog.cpp \
  31         keypressforwarder.cpp
  32     PLATFORM_HEADERS= \
  33         app.h \
  34         stationlistview.h \
  35         keypressforwarder.h \
  36         settingsdialog.h \
  37         stationview.h
  38 }
  39 symbian {
  40     QT += declarative
  41     DEFINES += TARGET_PLATFORM_SYMBIAN
  42     PLATFORM = symbian
  43     PLATFORM_SOURCES = view.cpp
  44     PLATFORM_HEADERS = view.h
  45 }
  46 !harmattan:!maemo5:!symbian {
  47     PLATFORM = desktop
  48     DEFINES += TARGET_PLATFORM_DESKTOP
  49     PLATFORM_SOURCES = view.cpp
  50 }
  51
  52 message(Compiling For:    $$PLATFORM)
  53 message(Platform Sources: $$PLATFORM_SOURCES)
  54 message(Qt Modules Used:  $$QT)
  55 message(Building version: $$VERSION)
  56
  57 CONFIG += qt webkit mobility
  58 MOBILITY = location
  59
  60 TARGET = quandoparte
  61 TEMPLATE = app
  62 VERSION_STRING = '\\"$${VERSION}\\"'
  63 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  64
  65 !debug {
  66 #    DEFINES += QT_NO_DEBUG_OUTPUT
  67 }
  68
  69 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  70
  71 SOURCES += \
  72     $$PLATFORM_SOURCES \
  73     main.cpp \
  74     stationlistmodel.cpp \
  75     stationlistproxymodel.cpp
  76
  77 HEADERS += \
  78     $$PLATFORM_HEADERS \
  79     stationlistmodel.h \
  80     stationlistproxymodel.h
  81
  82 FORMS += \
  83     settingsdialog.ui \
  84     stationlistview.ui
  85
  86 symbian {
  87     TARGET.UID3 = 0xe30fb688
  88     # TARGET.CAPABILITY +=
  89     TARGET.EPOCSTACKSIZE = 0x14000
  90     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  91 }
  92
  93 OTHER_FILES += \
  94     resources/harmattan/applications/quandoparte.desktop \
  95     resources/fremantle/applications/quandoparte.desktop \
  96     icons/48x48/quandoparte.png \
  97     icons/64x64/quandoparte.png \
  98     icons/scalable/quandoparte.svg \
  99     icons/quandoparte.png \
 100     resources/quandoparte.css \
 101     resources/arrivals.css \
 102     resources/departures.css \
 103     $$replace(TRANSLATIONS, .ts, .qm) \
 104     resources/stations/stations.qpl \
 105     resources/stations/generatelist.xq \
 106     resources/stations/generateunclassifiedlist.xq \
 107     resources/harmattan/qml/main.qml \
 108     resources/harmattan/qml/StationListPage.qml
 109
 110 unix {
 111     isEmpty(PREFIX) {
 112         maemo5 {
 113             PREFIX=/opt/usr
 114         } else {
 115             PREFIX=/usr/local
 116         }
 117     }
 118     maemo5 {
 119         DESKTOPDIR=/usr/share/applications/hildon
 120     } else {
 121         DESKTOPDIR=$$PREFIX/share/applications
 122     }
 123
 124     BINDIR=$$PREFIX/bin
 125     DATADIR=$$PREFIX/share/apps/$${TARGET}
 126     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 127 }
 128
 129 message(Installing to prefix $$PREFIX)
 130
 131 unix:!symbian {
 132     target.path = $$BINDIR
 133     INSTALLS += target
 134 }
 135
 136 unix:!symbian {
 137     desktopfile.files = resources/$$PLATFORM/applications/$${TARGET}.desktop
 138     desktopfile.path = $$DESKTOPDIR
 139     INSTALLS += desktopfile
 140 }
 141
 142 unix:!symbian {
 143     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 144     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 145     stations.files = resources/stations/stations.qpl
 146
 147     i18n.path = $$DATADIR/i18n
 148     css.path = $$DATADIR/css
 149     stations.path = $$DATADIR/stations
 150
 151     icon48.files = icons/48x48/$${TARGET}.png
 152     icon64.files = icons/64x64/$${TARGET}.png
 153     iconscalable.files = icons/scalable/$${TARGET}.svg
 154
 155     icon48.path = /usr/share/icons/hicolor/48x48/apps
 156     icon64.path = /usr/share/icons/hicolor/64x64/apps
 157     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 158
 159     INSTALLS += icon48
 160     INSTALLS += icon64
 161     INSTALLS += iconscalable
 162     INSTALLS += css
 163     INSTALLS += i18n
 164     INSTALLS += stations
 165 }
 166
 167 harmattan {
 168     qml.files = resources/harmattan/qml/*.qml
 169     qml.path = $$DATADIR/qml
 170     INSTALLS += qml
 171 }