git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 VERSION = 0.4.80
   8
   9 QT += webkit network
  10
  11 harmattan {
  12     QT += declarative
  13     PLATFORM = harmattan
  14     DEFINES += TARGET_PLATFORM_HARMATTAN
  15     # enable booster
  16     CONFIG += qdeclarative-boostable
  17     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden
  18     QMAKE_LFLAGS += -pie -rdynamic
  19     PLATFORM_SOURCES = view.cpp
  20     PLATFORM_HEADERS = view.h
  21 }
  22 maemo5 {
  23     QT += maemo5
  24     PLATFORM = fremantle
  25     DEFINES += TARGET_PLATFORM_FREMANTLE
  26     PLATFORM_SOURCES = \
  27         app.cpp \
  28         stationlistview.cpp \
  29         stationview.cpp \
  30         settingsdialog.cpp \
  31         keypressforwarder.cpp
  32     PLATFORM_HEADERS= \
  33         app.h \
  34         stationlistview.h \
  35         keypressforwarder.h \
  36         settingsdialog.h \
  37         stationview.h
  38 }
  39 symbian {
  40     QT += declarative
  41     DEFINES += TARGET_PLATFORM_SYMBIAN
  42     PLATFORM = symbian
  43     PLATFORM_SOURCES = view.cpp
  44     PLATFORM_HEADERS = view.h
  45 }
  46 !harmattan:!maemo5:!symbian {
  47     PLATFORM = desktop
  48     DEFINES += TARGET_PLATFORM_DESKTOP
  49     PLATFORM_SOURCES = view.cpp
  50 }
  51
  52 message(Compiling For:    $$PLATFORM)
  53 message(Platform Sources: $$PLATFORM_SOURCES)
  54 message(Qt Modules Used:  $$QT)
  55 message(Building version: $$VERSION)
  56
  57 CONFIG += qt webkit mobility
  58 MOBILITY = location
  59
  60 TARGET = quandoparte
  61 TEMPLATE = app
  62 VERSION_STRING = '\\"$${VERSION}\\"'
  63 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  64
  65 !debug {
  66 #    DEFINES += QT_NO_DEBUG_OUTPUT
  67 }
  68
  69 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  70
  71 SOURCES += \
  72     $$PLATFORM_SOURCES \
  73     main.cpp \
  74     stationlistmodel.cpp \
  75     stationlistproxymodel.cpp \
  76     settings.cpp \
  77     dataprovider.cpp \
  78     stationschedulemodel.cpp \
  79     stationscheduleitem.cpp
  80
  81 HEADERS += \
  82     $$PLATFORM_HEADERS \
  83     stationlistmodel.h \
  84     stationlistproxymodel.h \
  85     settings.h \
  86     dataprovider.h \
  87     stationschedulemodel.h \
  88     stationscheduleitem.h
  89
  90 FORMS += \
  91     settingsdialog.ui \
  92     stationlistview.ui
  93
  94 symbian {
  95     TARGET.UID3 = 0xe30fb688
  96     # TARGET.CAPABILITY +=
  97     TARGET.EPOCSTACKSIZE = 0x14000
  98     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  99 }
 100
 101 OTHER_FILES += \
 102     resources/harmattan/applications/quandoparte.desktop \
 103     resources/fremantle/applications/quandoparte.desktop \
 104     icons/48x48/quandoparte.png \
 105     icons/64x64/quandoparte.png \
 106     icons/scalable/quandoparte.svg \
 107     icons/quandoparte.png \
 108     resources/quandoparte.css \
 109     resources/arrivals.css \
 110     resources/departures.css \
 111     $$replace(TRANSLATIONS, .ts, .qm) \
 112     resources/stations/stations.qpl \
 113     resources/stations/generatelist.xq \
 114     resources/stations/generateunclassifiedlist.xq \
 115     resources/harmattan/qml/main.qml \
 116     resources/harmattan/qml/StationListPage.qml \
 117     resources/harmattan/qml/StationPage.qml \
 118     resources/harmattan/qml/SearchBar.qml \
 119     resources/harmattan/qml/PageHeader.qml \
 120     resources/harmattan/qml/uiconstants.js \
 121     resources/harmattan/qml/StationListPage.js \
 122     resources/harmattan/qml/AboutPage.qml \
 123     resources/harmattan/qml/InfoBar.qml
 124
 125 unix {
 126     isEmpty(PREFIX) {
 127         maemo5 {
 128             PREFIX=/opt/usr
 129         } else {
 130             PREFIX=/usr/local
 131         }
 132     }
 133     maemo5 {
 134         DESKTOPDIR=/usr/share/applications/hildon
 135     } else {
 136         DESKTOPDIR=$$PREFIX/share/applications
 137     }
 138
 139     BINDIR=$$PREFIX/bin
 140     DATADIR=$$PREFIX/share/apps/$${TARGET}
 141     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 142 }
 143
 144 message(Installing to prefix $$PREFIX)
 145
 146 unix:!symbian {
 147     target.path = $$BINDIR
 148     INSTALLS += target
 149 }
 150
 151 unix:!symbian {
 152     desktopfile.files = resources/$$PLATFORM/applications/$${TARGET}.desktop
 153     desktopfile.path = $$DESKTOPDIR
 154     INSTALLS += desktopfile
 155 }
 156
 157 unix:!symbian {
 158     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 159     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 160     stations.files = resources/stations/stations.qpl
 161
 162     i18n.path = $$DATADIR/i18n
 163     css.path = $$DATADIR/css
 164     stations.path = $$DATADIR/stations
 165
 166     icon48.files = icons/48x48/$${TARGET}.png
 167     icon64.files = icons/64x64/$${TARGET}.png
 168     iconscalable.files = icons/scalable/$${TARGET}.svg
 169
 170     icon48.path = /usr/share/icons/hicolor/48x48/apps
 171     icon64.path = /usr/share/icons/hicolor/64x64/apps
 172     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 173
 174     INSTALLS += icon48
 175     INSTALLS += icon64
 176     INSTALLS += iconscalable
 177     INSTALLS += css
 178     INSTALLS += i18n
 179     INSTALLS += stations
 180 }
 181
 182 harmattan {
 183     qml.files = resources/harmattan/qml/*.qml resources/harmattan/qml/*.js
 184     qml.path = $$DATADIR/qml
 185     INSTALLS += qml
 186 }
 187
 188