git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 VERSION = 0.5.1
   8 USE_RESOURCES = 0
   9
  10 QT += network
  11 CONFIG += qt thread
  12 CONFIG += link_pkgconfig
  13
  14 greaterThan(QT_MAJOR_VERSION, 5) {
  15     QT += qml quick concurrent location widgets webkitwidgets webkit
  16     CONFIG += qml quick concurrent location
  17     #PKGCONFIG += Qt5WebKitWidgets Qt5Location Qt5Quick
  18 }
  19 lessThan(QT_MAJOR_VERSION, 5) {
  20     QT += webkit
  21     CONFIG += webkit mobility
  22     MOBILITY = location
  23 }
  24
  25 contains(MEEGO_EDITION, harmattan) {
  26     CONFIG += harmattan
  27 }
  28
  29 sailfish {
  30     PLATFORM = sailfish
  31     DEFINES += TARGET_PLATFORM_SAILFISH
  32     # enable booster
  33 packagesExist(qdeclarative-boostable) {
  34     message("Building with qdeclarative-boostable support")
  35     DEFINES += HAS_BOOSTER
  36     PKGCONFIG += qdeclarative-boostable
  37 } else {
  38     warning("qdeclarative-boostable not available; startup times will be slower")
  39 }
  40     QMAKE_LFLAGS += -pie -rdynamic
  41     PLATFORM_SOURCES = view.cpp
  42     PLATFORM_HEADERS = view.h
  43 }
  44 harmattan {
  45     QT += declarative
  46     PLATFORM = harmattan
  47     DEFINES += TARGET_PLATFORM_HARMATTAN
  48     # enable booster
  49     CONFIG += qdeclarative-boostable
  50     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden -Wno-psabi
  51     QMAKE_LFLAGS += -pie -rdynamic
  52     PLATFORM_SOURCES = view.cpp
  53     PLATFORM_HEADERS = view.h
  54 }
  55 maemo5 {
  56     QT += maemo5
  57     PLATFORM = fremantle
  58     DEFINES += TARGET_PLATFORM_FREMANTLE
  59     PLATFORM_SOURCES = \
  60         app.cpp \
  61         stationlistview.cpp \
  62         stationview.cpp \
  63         settingsdialog.cpp \
  64         keypressforwarder.cpp
  65     PLATFORM_HEADERS= \
  66         app.h \
  67         stationlistview.h \
  68         keypressforwarder.h \
  69         settingsdialog.h \
  70         stationview.h
  71 }
  72 symbian {
  73     QT += declarative
  74     DEFINES += TARGET_PLATFORM_SYMBIAN
  75     PLATFORM = symbian
  76     PLATFORM_SOURCES = view.cpp
  77     PLATFORM_HEADERS = view.h
  78 }
  79 !sailfish:!harmattan:!maemo5:!symbian {
  80     PLATFORM = desktop
  81     DEFINES += TARGET_PLATFORM_DESKTOP
  82     PLATFORM_SOURCES = view.cpp
  83 }
  84
  85 message(Compiling For:    $$PLATFORM)
  86 message(Platform Sources: $$PLATFORM_SOURCES)
  87 message(Qt Version:       $$QT_MAJOR_VERSION $$QT_MINOR_VERSION)
  88 message(Qt Modules Used:  $$QT)
  89 message(Building version: $$VERSION)
  90
  91 TARGET = quandoparte
  92 TEMPLATE = app
  93 VERSION_STRING = '\\"$${VERSION}\\"'
  94 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  95
  96 contains(USE_RESOURCES,1) {
  97     DEFINES += USE_RESOURCES=1
  98 }
  99
 100 !debug {
 101     DEFINES += QT_NO_DEBUG_OUTPUT
 102 }
 103
 104 TRANSLATIONS = resources/i18n/quandoparte_it.ts
 105
 106 SOURCES += \
 107     $$PLATFORM_SOURCES \
 108     main.cpp \
 109     stationlistmodel.cpp \
 110     stationlistproxymodel.cpp \
 111     settings.cpp \
 112     dataprovider.cpp \
 113     stationschedulemodel.cpp \
 114     stationscheduleitem.cpp
 115
 116 HEADERS += \
 117     $$PLATFORM_HEADERS \
 118     stationlistmodel.h \
 119     stationlistproxymodel.h \
 120     settings.h \
 121     dataprovider.h \
 122     stationschedulemodel.h \
 123     stationscheduleitem.h
 124
 125 FORMS += \
 126     settingsdialog.ui \
 127     stationlistview.ui
 128
 129 symbian {
 130     TARGET.UID3 = 0xe30fb688
 131     # TARGET.CAPABILITY +=
 132     TARGET.EPOCSTACKSIZE = 0x14000
 133     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
 134 }
 135
 136 QMLSOURCES = \
 137     resources/harmattan/qml/main.qml \
 138     resources/harmattan/qml/StationListPage.qml \
 139     resources/harmattan/qml/StationPage.qml \
 140     resources/harmattan/qml/SearchBar.qml \
 141     resources/harmattan/qml/PageHeader.qml \
 142     resources/harmattan/qml/PageHeader.js \
 143     resources/harmattan/qml/uiconstants.js \
 144     resources/harmattan/qml/StationListPage.js \
 145     resources/harmattan/qml/AboutPage.qml \
 146     resources/harmattan/qml/InfoBar.qml \
 147     resources/harmattan/qml/DroppedShadow.qml \
 148     resources/harmattan/qml/DelayIndicator.qml \
 149     resources/harmattan/qml/StationScheduleDelegate.qml
 150
 151 OTHER_FILES += \
 152     resources/harmattan/applications/quandoparte.desktop \
 153     resources/fremantle/applications/quandoparte.desktop \
 154     icons/48x48/quandoparte.png \
 155     icons/64x64/quandoparte.png \
 156     icons/80x80/quandoparte.png \
 157     icons/scalable/quandoparte.svg \
 158     icons/sailfish/90x90/quandoparte.svg \
 159     icons/sailfish/scalable/quandoparte.svg \
 160     icons/quandoparte.png \
 161     resources/quandoparte.css \
 162     resources/arrivals.css \
 163     resources/departures.css \
 164     $$replace(TRANSLATIONS, .ts, .qm) \
 165     resources/stations/stations.qpl \
 166     resources/stations/generatelist.xq \
 167     resources/stations/generateunclassifiedlist.xq \
 168     $$QMLSOURCES
 169
 170 unix {
 171     isEmpty(PREFIX) {
 172         maemo5 {
 173             PREFIX=/opt/usr
 174         }
 175         harmattan {
 176             PREFIX=/opt/$${TARGET}
 177         }
 178         sailfish:desktop {
 179             PREFIX=/usr/local
 180         }
 181     }
 182     maemo5 {
 183         DESKTOPDIR=/usr/share/applications/hildon
 184     }
 185     harmattan {
 186         DESKTOPDIR=/usr/share/applications
 187     }
 188     sailfish {
 189         DESKTOPDIR=$$PREFIX/share/applications
 190     }
 191     desktop {
 192         DESKTOPDIR=$$PREFIX/share/applications
 193     }
 194
 195     BINDIR=$$PREFIX/bin
 196     contains(USE_RESOURCES,1) {
 197         DATADIR=":"
 198     } else {
 199         DATADIR=$$PREFIX/share/apps/$${TARGET}
 200     }
 201     DEFINES += DATADIR=\\\"$${DATADIR}\\\" PKGDATADIR=\\\"$${PKGDATADIR}\\\"
 202 }
 203
 204 message(Installing to prefix $$PREFIX)
 205
 206 unix:!symbian {
 207     target.path = $$BINDIR
 208     INSTALLS += target
 209 }
 210
 211 unix:!symbian {
 212     desktopfile.files = resources/$$PLATFORM/applications/$${TARGET}.desktop
 213     desktopfile.path = $$DESKTOPDIR
 214     INSTALLS += desktopfile
 215 }
 216
 217 unix:!symbian {
 218     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 219     stations.files = resources/stations/stations.qpl
 220
 221     i18n.path = $$DATADIR/i18n
 222     stations.path = $$DATADIR/stations
 223
 224     icon48.files = icons/48x48/$${TARGET}.png
 225     icon64.files = icons/64x64/$${TARGET}.png
 226     iconscalable.files = icons/scalable/$${TARGET}.svg
 227
 228     icon48.path = /usr/share/icons/hicolor/48x48/apps
 229     icon64.path = /usr/share/icons/hicolor/64x64/apps
 230     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 231
 232     INSTALLS += icon48
 233     INSTALLS += iconscalable
 234     !contains(USE_RESOURCES,1) {
 235         INSTALLS += i18n
 236         INSTALLS += stations
 237     }
 238 }
 239
 240 maemo5 {
 241     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 242     css.path = $$DATADIR/css
 243     !contains(USE_RESOURCES,1) {
 244         INSTALLS += css
 245     }
 246 }
 247
 248 sailfish {
 249     icon90.files = icons/sailfish/90x90/$${TARGET}.png
 250     icon90.path = /usr/share/icons/hicolor/meegotouch/apps
 251     INSTALLS += icon90
 252 }
 253 harmattan {
 254     icon80.files = icons/80x80/$${TARGET}.png
 255     icon80.path = /usr/share/icons/hicolor/meegotouch/apps
 256     INSTALLS += icon80
 257 }
 258
 259 !contains(USE_RESOURCES,1) {
 260     harmattan {
 261         qml.files = resources/harmattan/qml/*.qml resources/harmattan/qml/*.js
 262         qml.path = $$DATADIR/qml
 263         INSTALLS += qml
 264     }
 265 }
 266
 267 contains(USE_RESOURCES,1) {
 268     RESOURCES += \
 269         quandoparte.qrc
 270 }
 271
 272 hack_to_fix_translations {
 273     SOURCES += $$QMLSOURCES
 274 }