git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 VERSION = 0.4.80
   8 USE_RESOURCES=0
   9
  10 QT += webkit network
  11 CONFIG += qt webkit mobility
  12 MOBILITY = location
  13
  14 contains(MEEGO_EDITION,harmattan) {
  15     CONFIG += harmattan
  16 }
  17
  18 harmattan {
  19     QT += declarative
  20     PLATFORM = harmattan
  21     DEFINES += TARGET_PLATFORM_HARMATTAN
  22     # enable booster
  23     CONFIG += qdeclarative-boostable
  24     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden -Wno-psabi
  25     QMAKE_LFLAGS += -pie -rdynamic
  26     PLATFORM_SOURCES = view.cpp
  27     PLATFORM_HEADERS = view.h
  28 }
  29 maemo5 {
  30     QT += maemo5
  31     PLATFORM = fremantle
  32     DEFINES += TARGET_PLATFORM_FREMANTLE
  33     PLATFORM_SOURCES = \
  34         app.cpp \
  35         stationlistview.cpp \
  36         stationview.cpp \
  37         settingsdialog.cpp \
  38         keypressforwarder.cpp
  39     PLATFORM_HEADERS= \
  40         app.h \
  41         stationlistview.h \
  42         keypressforwarder.h \
  43         settingsdialog.h \
  44         stationview.h
  45 }
  46 symbian {
  47     QT += declarative
  48     DEFINES += TARGET_PLATFORM_SYMBIAN
  49     PLATFORM = symbian
  50     PLATFORM_SOURCES = view.cpp
  51     PLATFORM_HEADERS = view.h
  52 }
  53 !harmattan:!maemo5:!symbian {
  54     PLATFORM = desktop
  55     DEFINES += TARGET_PLATFORM_DESKTOP
  56     PLATFORM_SOURCES = view.cpp
  57 }
  58
  59 message(Compiling For:    $$PLATFORM)
  60 message(Platform Sources: $$PLATFORM_SOURCES)
  61 message(Qt Modules Used:  $$QT)
  62 message(Building version: $$VERSION)
  63
  64 TARGET = quandoparte
  65 TEMPLATE = app
  66 VERSION_STRING = '\\"$${VERSION}\\"'
  67 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  68
  69 contains(USE_RESOURCES,1) {
  70     DEFINES += USE_RESOURCES=1
  71 }
  72
  73 !debug {
  74 #    DEFINES += QT_NO_DEBUG_OUTPUT
  75 }
  76
  77 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  78
  79 SOURCES += \
  80     $$PLATFORM_SOURCES \
  81     main.cpp \
  82     stationlistmodel.cpp \
  83     stationlistproxymodel.cpp \
  84     settings.cpp \
  85     dataprovider.cpp \
  86     stationschedulemodel.cpp \
  87     stationscheduleitem.cpp
  88
  89 HEADERS += \
  90     $$PLATFORM_HEADERS \
  91     stationlistmodel.h \
  92     stationlistproxymodel.h \
  93     settings.h \
  94     dataprovider.h \
  95     stationschedulemodel.h \
  96     stationscheduleitem.h
  97
  98 FORMS += \
  99     settingsdialog.ui \
 100     stationlistview.ui
 101
 102 symbian {
 103     TARGET.UID3 = 0xe30fb688
 104     # TARGET.CAPABILITY +=
 105     TARGET.EPOCSTACKSIZE = 0x14000
 106     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
 107 }
 108
 109 QMLSOURCES = \
 110     resources/harmattan/qml/main.qml \
 111     resources/harmattan/qml/StationListPage.qml \
 112     resources/harmattan/qml/StationPage.qml \
 113     resources/harmattan/qml/SearchBar.qml \
 114     resources/harmattan/qml/PageHeader.qml \
 115     resources/harmattan/qml/uiconstants.js \
 116     resources/harmattan/qml/StationListPage.js \
 117     resources/harmattan/qml/AboutPage.qml \
 118     resources/harmattan/qml/InfoBar.qml \
 119     resources/harmattan/qml/DroppedShadow.qml \
 120     resources/harmattan/qml/DelayIndicator.qml
 121
 122 OTHER_FILES += \
 123     resources/harmattan/applications/quandoparte.desktop \
 124     resources/fremantle/applications/quandoparte.desktop \
 125     icons/48x48/quandoparte.png \
 126     icons/64x64/quandoparte.png \
 127     icons/scalable/quandoparte.svg \
 128     icons/quandoparte.png \
 129     resources/quandoparte.css \
 130     resources/arrivals.css \
 131     resources/departures.css \
 132     $$replace(TRANSLATIONS, .ts, .qm) \
 133     resources/stations/stations.qpl \
 134     resources/stations/generatelist.xq \
 135     resources/stations/generateunclassifiedlist.xq \
 136     $$QMLSOURCES
 137
 138 unix {
 139     isEmpty(PREFIX) {
 140         maemo5 {
 141             PREFIX=/opt/usr
 142         }
 143         harmattan {
 144             PREFIX=/opt/$${TARGET}
 145         }
 146         desktop {
 147             PREFIX=/usr/local
 148         }
 149     }
 150     maemo5 {
 151         DESKTOPDIR=/usr/share/applications/hildon
 152     }
 153     harmattan {
 154         DESKTOPDIR=/usr/share/applications
 155     }
 156     desktop {
 157         DESKTOPDIR=$$PREFIX/share/applications
 158     }
 159
 160     BINDIR=$$PREFIX/bin
 161     DESKTOPDIR=$$PREFIX/share/applications
 162     contains(USE_RESOURCES,1) {
 163         DATADIR=":"
 164     } else {
 165         DATADIR=$$PREFIX/share/apps/$${TARGET}
 166     }
 167     DEFINES += DATADIR=\\\"$${DATADIR}\\\" PKGDATADIR=\\\"$${PKGDATADIR}\\\"
 168 }
 169
 170 message(Installing to prefix $$PREFIX)
 171
 172 unix:!symbian {
 173     target.path = $$BINDIR
 174     INSTALLS += target
 175 }
 176
 177 unix:!symbian {
 178     desktopfile.files = resources/$$PLATFORM/applications/$${TARGET}.desktop
 179     desktopfile.path = $$DESKTOPDIR
 180     INSTALLS += desktopfile
 181 }
 182
 183 unix:!symbian {
 184     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 185     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 186     stations.files = resources/stations/stations.qpl
 187
 188     i18n.path = $$DATADIR/i18n
 189     css.path = $$DATADIR/css
 190     stations.path = $$DATADIR/stations
 191
 192     icon48.files = icons/48x48/$${TARGET}.png
 193     icon64.files = icons/64x64/$${TARGET}.png
 194     iconscalable.files = icons/scalable/$${TARGET}.svg
 195
 196     icon48.path = /usr/share/icons/hicolor/48x48/apps
 197     icon64.path = /usr/share/icons/hicolor/64x64/apps
 198     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 199
 200     INSTALLS += icon48
 201     INSTALLS += icon64
 202     INSTALLS += iconscalable
 203     !contains(USE_RESOURCES,1) {
 204         INSTALLS += css
 205         INSTALLS += i18n
 206         INSTALLS += stations
 207     }
 208 }
 209
 210 !contains(USE_RESOURCES,1) {
 211     harmattan {
 212         qml.files = resources/harmattan/qml/*.qml resources/harmattan/qml/*.js
 213         qml.path = $$DATADIR/qml
 214         INSTALLS += qml
 215     }
 216 }
 217
 218 contains(USE_RESOURCES,1) {
 219     RESOURCES += \
 220         quandoparte.qrc
 221 }
 222
 223 hack_to_fix_translations {
 224     SOURCES += $$QMLSOURCES
 225 }