git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 VERSION = 0.4.80
   8
   9 QT += webkit network
  10
  11 harmattan {
  12     QT += declarative
  13     PLATFORM = harmattan
  14     DEFINES += TARGET_PLATFORM_HARMATTAN
  15     # enable booster
  16     CONFIG += qdeclarative-boostable
  17     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden
  18     QMAKE_LFLAGS += -pie -rdynamic
  19     PLATFORM_SOURCES = view.cpp
  20     PLATFORM_HEADERS = view.h
  21 }
  22 maemo5 {
  23     QT += maemo5
  24     PLATFORM = fremantle
  25     DEFINES += TARGET_PLATFORM_FREMANTLE
  26     PLATFORM_SOURCES = \
  27         app.cpp \
  28         stationlistview.cpp \
  29         stationview.cpp \
  30         settingsdialog.cpp \
  31         keypressforwarder.cpp
  32     PLATFORM_HEADERS= \
  33         app.h \
  34         stationlistview.h \
  35         keypressforwarder.h \
  36         settingsdialog.h \
  37         stationview.h
  38 }
  39 symbian {
  40     QT += declarative
  41     DEFINES += TARGET_PLATFORM_SYMBIAN
  42     PLATFORM = symbian
  43     PLATFORM_SOURCES = view.cpp
  44     PLATFORM_HEADERS = view.h
  45 }
  46 !harmattan:!maemo5:!symbian {
  47     PLATFORM = desktop
  48     DEFINES += TARGET_PLATFORM_DESKTOP
  49     PLATFORM_SOURCES = view.cpp
  50 }
  51
  52 message(Compiling For:    $$PLATFORM)
  53 message(Platform Sources: $$PLATFORM_SOURCES)
  54 message(Qt Modules Used:  $$QT)
  55 message(Building version: $$VERSION)
  56
  57 CONFIG += qt webkit mobility
  58 MOBILITY = location
  59
  60 TARGET = quandoparte
  61 TEMPLATE = app
  62 VERSION_STRING = '\\"$${VERSION}\\"'
  63 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  64
  65 !debug {
  66 #    DEFINES += QT_NO_DEBUG_OUTPUT
  67 }
  68
  69 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  70
  71 SOURCES += \
  72     $$PLATFORM_SOURCES \
  73     main.cpp \
  74     stationlistmodel.cpp \
  75     stationlistproxymodel.cpp \
  76     settings.cpp
  77
  78 HEADERS += \
  79     $$PLATFORM_HEADERS \
  80     stationlistmodel.h \
  81     stationlistproxymodel.h \
  82     settings.h
  83
  84 FORMS += \
  85     settingsdialog.ui \
  86     stationlistview.ui
  87
  88 symbian {
  89     TARGET.UID3 = 0xe30fb688
  90     # TARGET.CAPABILITY +=
  91     TARGET.EPOCSTACKSIZE = 0x14000
  92     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  93 }
  94
  95 OTHER_FILES += \
  96     resources/harmattan/applications/quandoparte.desktop \
  97     resources/fremantle/applications/quandoparte.desktop \
  98     icons/48x48/quandoparte.png \
  99     icons/64x64/quandoparte.png \
 100     icons/scalable/quandoparte.svg \
 101     icons/quandoparte.png \
 102     resources/quandoparte.css \
 103     resources/arrivals.css \
 104     resources/departures.css \
 105     $$replace(TRANSLATIONS, .ts, .qm) \
 106     resources/stations/stations.qpl \
 107     resources/stations/generatelist.xq \
 108     resources/stations/generateunclassifiedlist.xq \
 109     resources/harmattan/qml/main.qml \
 110     resources/harmattan/qml/StationListPage.qml \
 111     resources/harmattan/qml/StationPage.qml \
 112     resources/harmattan/qml/SearchBar.qml \
 113     resources/harmattan/qml/PageHeader.qml \
 114     resources/harmattan/qml/uiconstants.js
 115
 116 unix {
 117     isEmpty(PREFIX) {
 118         maemo5 {
 119             PREFIX=/opt/usr
 120         } else {
 121             PREFIX=/usr/local
 122         }
 123     }
 124     maemo5 {
 125         DESKTOPDIR=/usr/share/applications/hildon
 126     } else {
 127         DESKTOPDIR=$$PREFIX/share/applications
 128     }
 129
 130     BINDIR=$$PREFIX/bin
 131     DESKTOPDIR=$$PREFIX/share/applications
 132     DATADIR=$$PREFIX/share/apps/$${TARGET}
 133     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 134 }
 135
 136 message(Installing to prefix $$PREFIX)
 137
 138 unix:!symbian {
 139     target.path = $$BINDIR
 140     INSTALLS += target
 141 }
 142
 143 unix:!symbian {
 144     desktopfile.files = resources/$$PLATFORM/applications/$${TARGET}.desktop
 145     desktopfile.path = $$DESKTOPDIR
 146     INSTALLS += desktopfile
 147 }
 148
 149 unix:!symbian {
 150     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 151     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 152     stations.files = resources/stations/stations.qpl
 153
 154     i18n.path = $$DATADIR/i18n
 155     css.path = $$DATADIR/css
 156     stations.path = $$DATADIR/stations
 157
 158     icon48.files = icons/48x48/$${TARGET}.png
 159     icon64.files = icons/64x64/$${TARGET}.png
 160     iconscalable.files = icons/scalable/$${TARGET}.svg
 161
 162     icon48.path = /usr/share/icons/hicolor/48x48/apps
 163     icon64.path = /usr/share/icons/hicolor/64x64/apps
 164     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 165
 166     INSTALLS += icon48
 167     INSTALLS += icon64
 168     INSTALLS += iconscalable
 169     INSTALLS += css
 170     INSTALLS += i18n
 171     INSTALLS += stations
 172 }
 173
 174 harmattan {
 175     qml.files = resources/harmattan/qml/*.qml resources/harmattan/qml/*.js
 176     qml.path = $$DATADIR/qml
 177     INSTALLS += qml
 178 }